O comando “delay” do AppleScript não funciona desde a mudança para Yosemite

Nota: O problema com delayfoi corrigido no OS X 10.11 El Capitan.

Desde que atualizei para o Yosemite, os scripts de maçã que usam atrasos pararam de funcionar. Como posso consertar isso?

Aqui está o Applescript mais simples do mundo, para um exemplo fácil:

set volume output volume 0
delay 5
set volume output volume 20
delay 5
set volume output volume 0
delay 5
set volume output volume 20
delay 5
set volume output volume 0
delay 5
set volume output volume 20
delay 5
set volume output volume 0

Isso deve levar 30 segundos para ser concluído. Se eu executá-lo no Script Editor (anteriormente Applescript Editor), leva 30 segundos para ser concluído. Porém, se eu salvar esse script como um aplicativo, ao iniciá-lo, os atrasos serão ignorados e o aplicativo levará uma fração de segundo para ser concluído.

Como forçar o Applescript a adiar por um período especificado antes de prosseguir para a próxima etapa? Esta é uma falha de Yosemite? Existe uma solução alternativa confiável?

Nota: O problema com delayfoi corrigido no OS X 10.11 El Capitan.

@ 2oh1, você tem a idéia básica certa em sua resposta, mas aqui está uma resposta completa e correta:

A única maneira razoável de contornar isso é invocar o "atraso" dentro de um loop que garante a duração desejada antes de continuar. A melhor maneira de fazer isso é substituir o "atraso" por um manipulador personalizado:

on delay duration
  set endTime to (current date) + duration
  repeat while (current date) is less than endTime
    tell AppleScript to delay endTime - (current date)
  end repeat
end delay

Isso permite que você mantenha o restante do seu script inalterado e você pode usar o "atraso" normalmente, por exemplo,

delay 5
display alert "I like cake!"

[OBSERVAÇÃO: Normalmente, o manipulador personalizado usaria "continue delay duration" para chamar o "delay" interno, mas descobri que, embora isso funcione no Editor de scripts, ele retorna um erro quando usado em um applet ("Pode" t continue o atraso. (-1708) "). Eu resolvi esse problema dizendo diretamente ao AppleScript para manipular o comando delay em vez de usar "continue" para chegar lá.]

O problema é que delayprocessa a entrada do usuário durante a pausa do script, para que você ainda possa clicar nos menus ou janelas exibidos por um applet, e há um erro (corrigido no 10.11) em que a entrada do usuário faz delaycom que não espere a duração total antes de continuar a execução do script . Se você não interagir com o applet, delayfuncionará corretamente.

Enquanto lutava contra esse mesmo problema, me deparei com essa resposta para uma pergunta não tão relacionada e decidi tentar e parece funcionar para mim.

Simplesmente substitua delay 5por do shell script "/bin/sleep 5"e obtenha o mesmo resultado.

Não estou dizendo que esta é a melhor solução, mas parece que resolveu meu problema. Em vez de usar um atraso simples, que está sendo ignorado por razões que não entendo, mudei para obter o tempo e fazer um loop até chegar um novo horário (ele ainda usa um atraso, mas não importa se ignora o atraso, já que o script não continua até a hora chegar).

# Pause for five minutes
set GetTheTime to current date
set NewTime to GetTheTime + (5 * minutes)
repeat while (current date) is less than NewTime
    delay 60
end repeat

Ainda estou morrendo de vontade de saber por que o atraso está sendo ignorado (ou acelerado dramaticamente?! ??), mas isso faz o trabalho, por mais desajeitado que seja.

Encontrei uma solução alternativa em um post no fórum alemão . Adicione estas linhas na parte superior do seu script:

use framework "Foundation"
use scripting additions
current application's NSThread's sleepForTimeInterval:1

carzyj teve o que considero a melhor resposta, mas quando combinado com o método de Chris Page, você obtém:

on delay duration
  do shell script "/bin/sleep " & duration
end delay

Você pode comentar "em atraso" a "atraso final" para reverter para o atraso original.

esta é uma modificação na solução @ chris-page

Parece haver um equilíbrio entre a capacidade de resposta e a captura precisa do atraso.

on delay duration
    set endTime to (current date) + duration
    repeat while (current date) is less than endTime
        set delta to duration / 100
        if duration < 0.2 then
            set delta to 0.2
        end if
        tell AppleScript to delay delta
    end repeat
end delay

Mas, em vez de dizer ao Applescript para adiar a duração geral, apenas pedimos que adie por um período fracionário da duração. se o período for menor do que o permitido pela maçã (1/60 de segundo), vamos configurá-lo para esse delta. Que podemos manter alguma capacidade de resposta, mas ainda assim sermos precisos. a suspeita é que, às vezes, o atraso não funcione, e o loop repeat while manterá o encadeamento bloqueado, mas em cenários de sucesso, queremos que o delta do atraso seja curto para que o processo ainda possa ser interrompido

Então, para juntar tudo, acredito que Chris quer dizer isso:

on delay duration
   set endTime to (current date) + duration
   repeat while (current date) is less than endTime
      tell AppleScript to delay endTime - (current date)
   end repeat
end delay