Mostrar discriminação de uso de dados e disco por tabela

Eu tenho um banco de dados do SQL Server 2008 R2 sendo usado por vários programas implantados.

Pergunta: Existe uma maneira fácil de exibir quanto espaço cada tabela consome, para todas as tabelas no banco de dados, e distinguir espaço lógico de espaço em disco?

Se eu usar o SSMS (Management Studio), as propriedades de armazenamento mostradas no banco de dados exibem 167 MB com 3 MB "disponíveis" (aproximadamente o tamanho certo, mas estou preocupado com os 3 MB disponíveis - este é um limite para se preocupar , supondo que eu saiba que tenho espaço em disco suficiente?)

Eu posso detalhar cada tabela, mas isso leva uma eternidade para fazer.

Sei que posso escrever minhas próprias consultas e testar, mas gostaria de saber se já existe uma maneira fácil (integrada?) De fazer isso.

No SSMS, clique com o botão direito do mouse no banco de dados e vá para "Relatórios", "Relatórios padrão", "Uso de disco por tabela". Ele informará o tamanho total, o tamanho dos dados, o tamanho do índice e o tamanho não utilizado de cada tabela (assim como a contagem de linhas).

Foi respondido no Stack Overflow:

SELECT 
    t.NAME AS TableName,
    s.Name AS SchemaName,
    p.rows AS RowCounts,
    SUM(a.total_pages) * 8 AS TotalSpaceKB, 
    SUM(a.used_pages) * 8 AS UsedSpaceKB, 
    (SUM(a.total_pages) - SUM(a.used_pages)) * 8 AS UnusedSpaceKB
FROM 
    sys.tables t
INNER JOIN      
    sys.indexes i ON t.OBJECT_ID = i.object_id
INNER JOIN 
    sys.partitions p ON i.object_id = p.OBJECT_ID AND i.index_id = p.index_id
INNER JOIN 
    sys.allocation_units a ON p.partition_id = a.container_id
LEFT OUTER JOIN 
    sys.schemas s ON t.schema_id = s.schema_id
WHERE 
    t.NAME NOT LIKE 'dt%' 
    AND t.is_ms_shipped = 0
    AND i.OBJECT_ID > 255 
GROUP BY 
    t.Name, s.Name, p.Rows
ORDER BY 
    t.Name

A consulta vinculada e copiada por @Nelson é imprecisa: ignora as exibições indexadas, os índices de texto completo, os índices XML, etc.

Se você deseja uma consulta que inclua tudo sem executar sp_spaceusedvia sp_MSForEachTable, então eu já publiquei duas variações (uma aqui no DBA.StackExchange e a outra no StackOverflow) para não copiá-las aqui:

• Por cada tabela / exibição indexada: sp_spaceused - Como medir o tamanho em GB em todas as tabelas no SQL

• Por cada índice: uso de espaço em sys.allocation_units e sp_spaceused

Apenas por diversão, aqui está uma consulta que irá gerar os mesmos dados que o relatório na resposta de nateirvin

create table #disk_usage
(
    name varchar(128)
    ,rows varchar(20)
    ,reserved varchar(20)
    ,data varchar(20)
    ,index_size varchar(20)
    ,unused varchar(20)
);

exec sp_msforeachtable 'insert into #disk_usage exec sp_spaceused [?]'

select SCHEMA_NAME(st.schema_id) + '.' + du.name 'Table Name'
 ,du.rows '# Records'
 ,du.reserved 'Reserved (KB)'
 ,du.data 'Data (KB)'
 ,du.index_size 'Indexes (KB)'
 ,du.unused 'Unused (KB)'
 from #disk_usage du
left join sys.tables st
on du.name = st.name
order by cast(left(reserved, len(reserved) - 3) as bigint) desc;

drop table #disk_usage

Ok, porque eu realmente me odeio, escrevi uma consulta que irá gerar os resultados do relatório, formatá-lo como uma tabela HTML e enviá-lo como um email. A correspondência das cores de plano de fundo do relatório é deixada como um exercício para o leitor.

declare @subject nvarchar(25) = 'Disk Usage by Top Tables';

declare @recipients nvarchar(25) = '[email protected]';

create table #disk_usage
(
    name varchar(128)
    ,rows varchar(20)
    ,reserved varchar(20)
    ,data varchar(20)
    ,index_size varchar(20)
    ,unused varchar(20)
);

exec sp_msforeachtable 'insert into #disk_usage EXEC sp_spaceused [?]'

declare @body nvarchar(max) = 
'<table cellspacing="0">
    <thead>
        <tr>
            <th>Table Name</th>
            <th># Rows</th>
            <th>Reserved</th>
            <th>Data</th>
            <th>Indexes</th>
            <th>Unused</th>
        </tr>
    </thead>
';

set @body = @body + cast (
    (select '<td style="border: 1px solid black; padding: 2px">' + SCHEMA_NAME(s.schema_id) + '.' + t.name + '</td>'
     ,'<td style="border: 1px solid black; padding: 2px">' + rtrim(ltrim(t.rows)) + ' Rows </td>' -- for some reason this was generating a bunch of extra white space and I'm not going to bother to figure out why
     ,'<td style="border: 1px solid black; padding: 2px">' + t.reserved + '</td>'
     ,'<td style="border: 1px solid black; padding: 2px">' + t.data + '</td>'
     ,'<td style="border: 1px solid black; padding: 2px">' + t.index_size + '</td>'
     ,'<td style="border: 1px solid black; padding: 2px">' + t.unused + '</td>'
     from #disk_usage t
    left join sys.tables s
    on t.name = s.name
    order by cast(left(reserved, len(reserved) - 3) as bigint) desc
    for xml path ('tr'))
as nvarchar(max));

set @body = replace(replace(@body, '&lt;', '<'), '&gt;', '>')
set @body = @body + '</table>'

exec msdb.dbo.sp_send_dbmail 
@profile_name='A Database Mail Profile On The Target Server', 
@recipients=@recipients, 
@subject=@subject,
@body=@body,
@body_format='HTML'

drop table #disk_usage