Como transpor dois argumentos de uma função em Python?

Como posso trocar dois argumentos em uma chamada para uma função Python?

Se eu colocar pointo espaço entre esses dois argumentos:

self.assertEqual(json.loads(some.data), json_data)

e então M-t( transpose-words), eu recebo:

self.assertEqual(json.loads(some.json), data_data)

Por outro lado, com CMt ( transpose-sexps) eu recebo:

self.assertEqual(json.loadsjson_data, (some.data))

O que eu quero é:

self.assertEqual(json_data, json.loads(some.data))

Existe um comando que fará isso?

Isso também é algo que eu queria ter há muito tempo, e aqui encontrei alguma motivação para trabalhar nisso. Provavelmente não é muito robusto, mas na primeira tentativa parece cobrir os casos que tentei:

(defun my/calculate-stops ()
  (save-excursion
    (let ((start
           (condition-case e
               (while t (backward-sexp))
             (error (point))))
          stops)
      (push start stops)
      (condition-case e
          (while t
            (forward-sexp)
            (when (looking-at "\\s-*,")
              (push (point) stops)))
        (error (push (point) stops)))
      (nreverse stops))))

(defun my/transpose-args ()
  (interactive)
  (when (looking-at "\\s-") (backward-sexp))
  (cl-loop with p = (point)
           with previous = nil
           for stop on (my/calculate-stops)
           for i upfrom 0
           when (<= p (car stop)) do
           (when previous
             (let* ((end (cadr stop))
                    (whole (buffer-substring previous end))
                    middle last)
               (delete-region previous end)
               (goto-char previous)
               (setf middle (if (> i 1) (- (car stop) previous)
                              (string-match "[^, \\t]" whole 
                                            (- (car stop) previous)))
                     last (if (> i 1) (substring whole 0 middle)
                            (concat (substring whole (- (car stop) previous) middle)
                                    (substring whole 0 (- (car stop) previous)))))
               (insert (substring whole middle) last)))
           (cl-return)
           end do (setf previous (car stop))))

Eu uso uma variação transpose-sexpsque procura o caso que você descreve e transpõe as coisas separadas por vírgulas, ou apenas faz regular transpose-sexps. Ele também deixa o cursor no lugar em vez de arrastá-lo para frente, o que é um pouco diferente, mas eu pessoalmente gosto.

(defun my-transpose-sexps ()
  "If point is after certain chars transpose chunks around that.
Otherwise transpose sexps."
  (interactive "*")
  (if (not (looking-back "[,]\\s-*" (point-at-bol)))
      (progn (transpose-sexps 1) (forward-sexp -1))
    (let ((beg (point)) end rhs lhs)
      (while (and (not (eobp))
                  (not (looking-at "\\s-*\\([,]\\|\\s)\\)")))
        (forward-sexp 1))
      (setq rhs (buffer-substring beg (point)))
      (delete-region beg (point))
      (re-search-backward "[,]\\s-*" nil t)
      (setq beg (point))
      (while (and (not (bobp))
                  (not (looking-back "\\([,]\\|\\s(\\)\\s-*" (point-at-bol))))
        (forward-sexp -1))
      (setq lhs (buffer-substring beg (point)))
      (delete-region beg (point))
      (insert rhs)
      (re-search-forward "[,]\\s-*" nil t)
      (save-excursion
        (insert lhs)))))

Nos modos que usam o SMIE, transpose-sexpdeve funcionar corretamente para esse caso. Eles ainda falharão quando o símbolo do infix (também conhecido como "separador") não é um ,(ou a ;), mas é uma palavra (por exemplo and).

Portanto, minha opinião é que o comando para isso é transpose-sexpe, quando isso não funcionar corretamente, considero-o um bug (mas um bug que pode ser difícil e / ou levar tempo para corrigir e ter baixa prioridade, então não ' prenda a respiração). A maneira de corrigi-lo é definindo forward-sexp-functionuma função que saiba que "depois de ver uma vírgula, apenas pulo o argumento inteiro".