Salvando a trilha do Calc para uso posterior

Existe a possibilidade de salvar o Emacs Calculator Trail (como um arquivo) e restaurá-lo mais tarde? Caso contrário, deve ser um recurso?

Por exemplo, quando eu tenho um cálculo incompleto, mas preciso desligar meu Emacs, seria ótimo se eu pudesse continuar depois.

Segundo caso: faço alguns cálculos e quero armazenar como o fiz, para depois verificar se fiz corretamente ou se preciso modificá-lo.

A segunda razão é por que eu uso o MATLAB (eu sei demais) para pequenos cálculos, apenas para restaurá-los. Mas eu gostaria de usar apenas o Emacs Calc!

Obrigado pelas respostas

Como o processamento da trilha de cálculo é baseado em texto, é possível usar essencialmente write-regione insert-file-contents.

No entanto, alguns detalhes devem ser considerados. O código Elisp a seguir permite gravar o buffer de trilha de cálculo atual no disco C-x C-se você pode ler esse material na posição atual do cursor com C-x i.

Depois, você pode usar as calc-trail-modeligações para avaliar partes dos comandos de leitura de calc.

(defvar-local calc-trail-buffer-file-name nil
  "Like `buffer-file-name' for calc-trail buffers.")

(defun calc-trail-save (&optional filename)
  "Save current calc trail buffer.
To be used in `write-contents-functions'.
Append with current prefix arg."
  (interactive "FCalc Trail File: ")
  (unless filename
    (setq calc-trail-buffer-file-name
      (expand-file-name (setq filename
                  (read-file-name "Calc Trail File: " nil calc-trail-buffer-file-name)))))
    (when (null (derived-mode-p 'calc-trail-mode))
    (user-error "Saving calc trail buffers requires calc-trail-mode"))
  (save-point
   (save-restriction
     (widen)
     (let* ((b-trail (progn (goto-char 1) (1+ (line-end-position))))
        (b (progn (goto-char (max (or (and (use-region-p) (region-beginning)) (point-min)) b-trail))
              (line-beginning-position)))
        (e (progn (goto-char (max (or (and (use-region-p) (region-end)) (point-max)) b-trail))
              (line-end-position))))
       (write-region b e filename current-prefix-arg)))))

(defun calc-insert-file (filename)
  "Insert calc-trail file FILENAME at point."
  (interactive "FCalc trail file: ")
  (when (= (line-beginning-position) 1)
    (goto-char (1+ (line-end-position))))
  (goto-char (line-beginning-position
          (if (looking-at "[[:space:]]*$")
          2
        1)))
  (let ((inhibit-read-only t))
    (insert-file-contents filename)
    (when (and (null (looking-at "[[:space:]]*$"))
           (null (looking-back "^[[:space:]]*" (line-beginning-position))))
      (insert "\n"))))

(defun calc-trail-install-save ()
  "Install `calc-trail-save' in `write-contents-functions' of `calc-trail-mode' buffers."
  (push #'calc-trail-save write-contents-functions)
  (local-set-key (kbd "C-x i") #'calc-insert-file))

(add-hook 'calc-trail-mode-hook #'calc-trail-install-save)

você pode usar o s pque significa (calc-permanent-variable &optional VAR)salvar todas as variáveis ​​em ~/.emacs.d/calc.elou calc-settings-file.