Executando spacemacs ao lado de emacs regulares: como manter um arquivo .emacs.d separado

Eu gostaria de experimentar o spacemacs. Mas ainda não quero mudar da minha configuração regular do emacs, portanto, gostaria que a configuração que está atualmente no meu .emacs.desteja em um diretório e a configuração equivalente para o spacemacs esteja em outro diretório. Não me importo com o nome de nenhum diretório.

Isso é possível, sem chroots / LD_PRELOAD / outros truques desse tipo? Como eu posso fazer isso?

Uma opção é especificar qual configuração você deseja carregar em um ~/.emacsarquivo. Quando o Emacs inicia, ele procura esse arquivo antes de procurar ~/.emacs.d/. Para mais detalhes, você pode ler sobre o arquivo Init no manual do Emacs.

Por exemplo, você pode criar um ~/.spacemacs.de manter o seu existente ~/.emacs.dcomo ele é. Em seguida, crie um ~/.emacspara carregar o que você deseja usar:

(setq use-spacemacs t)   ; or nil 

(when use-spacemacs
  (setq user-emacs-directory "~/.spacemacs.d/"))   ; defaults to ~/.emacs.d/

(load (expand-file-name "init.el" user-emacs-directory))

Se você quiser, pode encontrar maneiras de mudar as configurações sem modificar o arquivo .emacs. Por exemplo, faça com que o seu .emacs verifique alguma variável de ambiente que você definiu no shell ou em um script usado para iniciar o spacemacs:

(setq use-spacemacs (getenv "USE_SPACEMACS"))

Como há mais o que fazer no init do que apenas carregar um arquivo e, por outro lado, desvincular .emacs.dou alterar HOMEalterações no meu ambiente de tempo de execução, optei por uma variante do que o @glucas havia proposto. Usei o código startup.ele adicionei o patch do # 15539 para usar uma variável de ambiente para alternar entre diferentes diretórios init. Se nenhum for fornecido, o padrão é usado.

Houve um problema com o spacemacs: asyncnão sabe sobre o diretório init alterado e, portanto, não consegue encontrar alguns arquivos necessários. Mas isso foi resolvido recentemente no spacemacs: Erro ao usar um diretório de configuração diferente de .emacs.d · Edição nº 3390

Então, aqui está o meu ~/.emacsque deve se comportar como o código init original, mas com o diretório init configurável:

;;; .emacs --- let the user choose the emacs environment to use

;;; Commentary:
;;; This code mimics the behaviour of `startup.el' to let the
;;; usage of the custom init directory behave just like the
;;; one and only "~/.emacs.d".
;;;
;;; By setting the environment variable `EMACS_USER_DIRECTORY'
;;; the user-emacs-directory can be chosen and if there is an
;;; `init.el' the configuration from that directory will be used.
;;; If the environment variable is not set or there is no `init.el'
;;; the default configuration directory `~/.emacs.d/' will be used.
;;;
;;; The variable `server-name' will be set to the name of the directory
;;; chosen as start path.  So if the server will be started, it can be
;;; reached with 'emacsclient -s servername'.
;;;
;;; This now works with a current version of spacemacs but does not
;;; work with `async-start' in general, if the code executed with `async'
;;; uses `user-init-dir' or makes other assumptions about the emacs
;;; start-directory.

;;; Code:
(let* ((user-init-dir-default
    (file-name-as-directory (concat "~" init-file-user "/.emacs.d")))
       (user-init-dir
    (file-name-as-directory (or (getenv "EMACS_USER_DIRECTORY")
                    user-init-dir-default)))
       (user-init-file-1
    (expand-file-name "init" user-init-dir)))
  (setq user-emacs-directory user-init-dir)
  (with-eval-after-load "server"
    (setq server-name
      (let ((server--name (file-name-nondirectory
                   (directory-file-name user-emacs-directory))))
        (if (equal server--name ".emacs.d")
        "server"
          server--name))))
  (setq user-init-file t)
  (load user-init-file-1 t t)
  (when (eq user-init-file t)
    (setq user-emacs-directory user-init-dir-default)
    (load (expand-file-name "init" user-init-dir-default) t t)))

(provide '.emacs)
;;; .emacs ends here

Há também uma boa adição que o faz funcionar como um daemon sem esforço extra: o nome do servidor será definido como o nome do diretório init. Então agora você pode iniciar um segundo daemon do emacs com um spacemacs de baunilha

EMACS_USER_DIRECTORY=~/.emacsenv.d/spacemacs emacs --daemon

e ainda use o emacsclient

emacsclient -s spacemacs -c -e '(message "Hello spacemacs")'

Meu caso de usuário é muito simples e estou surpreso por ser o único: tenho um daemon do emacs sempre em execução e o uso no gui e no console (com ssh por exemplo). Neste emacs, preparo toda a minha documentação e registro de trabalho, para que esteja lá o tempo todo. Mas então eu quero experimentar o spacemacs ou um dos outros pacotes de distribuição e até configurá-lo, até que eu possa aposentar minha configuração atual ou usar algumas das idéias inteligentes. E, como outros, eu queria criar uma configuração básica simples para meus colegas de trabalho - e documentá-la com o modo org na minha instância em execução.

Como o único problema que conheço é asynce ele não conhece o diretório init alterado, penso na melhor maneira de adicionar algumas configurações às asyncvariáveis ​​que devem ser injetadas por padrão, para que não seja necessário corrigir todos os invocações async-startexatamente como os spacemacs haviam feito.

É explicado aqui e há um PR em andamento para adicioná-lo à documentação:

mkdir ~/spacemacs
git clone [email protected]:syl20bnr/spacemacs.git ~/spacemacs/.emacs.d
HOME=~/spacemacs emacs```

Ele já foi respondido e aceito, mas se você quiser experimentar novas maneiras de fazer as coisas da maneira reversível (além das configurações do emacs), recomendo que você gaste meia hora se familiarizando com o GNU Stow. É uma espécie de ln -sesteróides, e pode haver várias abordagens para usá-lo. Você pode ter toda a configuração em um subdiretório (incluindo configurações offlineimap, configurações do emacs etc.) - isso seria uma abordagem baseada no ambiente - ou ter um subdiretório separado para cada aplicativo que você possui. Doce esquizofrenia.

Por exemplo, lista relacionada ao emacs do meu ~ / Stow:

-> % ls ~/Stow | grep emacs
emacs 
emacs_from_scratch
spacemacs
hoodoo@T450s 2:46 [~]

Há uma configuração inicial que eu consegui usar, uma configuração de 'eu fico com os padrões' e uma 'eu vou rolar sozinha'. Posso ativar e desativar cada uma delas e sempre tê-las disponíveis. Cada subdiretório pode ter uma árvore inteira em relação ao meu ~ / e é bastante útil misturar e combinar.

Eu verifiquei o patch que @Uwe Koloska usou. Não foi incluído no ramo principal. Concordo um pouco, acho que o problema deve ser resolvido fora do emacs usando o shell e deixando o emacs sem saber nada sobre isso.

Talvez esse recurso seja mais lógico da perspectiva do usuário, o uso de um sinalizador seria menos complicado para alguns usuários.

No meu caso de uso, quero manter minha instalação do Emacs e do Spacemacs para que minha variação das duas soluções acima funcione dessa maneira.

script de shell

Primeiro de tudo o script para iniciar o spacemacs:

#!/bin/sh

export EMACS_USER_DIR=~/spacemacs/emacs.d

exec emacs "$@"

Este script é chamado spacemacse está instalado na /usr/local/binpasta.

arquivo .emacs

Então eu preciso de um .emacsarquivo na minha pasta pessoal que trate corretamente a variável de ambiente EMACS_USER_DIR.

(defvar user-custom-dir (getenv "EMACS_USER_DIR"))

(when (/= (length user-custom-dir) 0)
  (setq user-emacs-directory (file-name-as-directory user-custom-dir)))

(load (expand-file-name "init.el" user-emacs-directory))

Eu não sou experiente com o elisp, então vim à tona, pessoas mais experientes provavelmente poderiam criar algo melhor. Mas ei, isso funciona.

Eye-candy

Então porque não adicionar um ícone:

[Desktop Entry]
Name=Spacemacs
GenericName=Text Editor
Comment=Edit text
MimeType=text/english;text/plain;text/x-makefile;text/x-c++hdr;text/x-c++src;text/x-chdr;text/x-csrc;text/x-java;text/x-moc;text/x-pascal;text/x-tcl;text/x-tex;application/x-shellscript;text/x-c;text/x-c++;
Exec=spacemacs %F
Icon=/home/marcs/.icons/spacemacs.svg
Type=Application
Terminal=false
Categories=Development;TextEditor;
StartupWMClass=Emacs
Keywords=Text;Editor;

Acho o uso do Chemacs muito fácil para alternar entre diferentes configurações do emacs.

Fiz uma resposta aqui: https://emacs.stackexchange.com/a/44678/11979 .