Maneira de ocultar delimitadores de bloco SRC

12

existe uma maneira de manter apenas o código-fonte dentro do código-fonte, ou seja, tornar # + BEGIN_SRC e # + END_SRC invisíveis? É cosmético, mas torna as coisas mais claras quando é preciso lidar com muitos trechos de código curto. Por exemplo:

(defun org-xor (a b)
          "Exclusive or."
          (if a (not b) b))

ao invés de :

  #+BEGIN_SRC emacs-lisp
       (defun org-xor (a b)
          "Exclusive or."
          (if a (not b) b))
  #+END_SRC
org-mode Loukios
fonte
Meu comentário abaixo da pergunta neste segmento semi-relacionado mostra como ocultar programaticamente os cabeçalhos / rodapés do bloco de origem. emacs.stackexchange.com/q/26163/2287 - ou seja, (save-excursion (goto-char (point-max)) (while (re-search-backward "#\\+BEGIN_SRC\\|#\\+END_SRC" nil t) (let ((ov (make-overlay (line-beginning-position) (1+ (line-end-position))))) (overlay-put ov 'invisible t)))) para mostrar tudo, use (remove-overlays). Mais trabalhos precisam ser feitos para entradas individuais e remover somente as sobreposições selecionadas (em vez de todas as sobreposições), mas essa é a ideia geral.
lawlist
Obrigado, isso é interessante ... Vou brincar com isso.
loukios 30/09/16

Respostas:

5

A face de todas as linhas iniciadas com #+é chamada org-meta-line.

Você pode personalizar esse rosto menor, mais escuro etc. para torná-lo menos visível.

Juancho
fonte
De fato. Como exemplo, eu o configurei usando (set-face-attribute 'org-meta-line nil :height 0.8 :slant 'normal). Acho que ajuda bastante.
Harald Hanche-Olsen
Obrigado pela sua resposta, isso ajuda. Eu mudei a altura btw, mas ela não tem nenhum efeito ...
loukios
Veja esta documentação Emacs Lisp sobre as opções que você pode atribuir a org-meta-line gnu.org/software/emacs/manual/html_node/elisp/...
salotz
4

Eu uso o seguinte trecho de código que é parte do caminho. Não é perfeito. Talvez isso se torne adequado minor-modealgum dia. ( fonte ).

Captura de tela do código resultante

(with-eval-after-load 'org
  (defvar-local rasmus/org-at-src-begin -1
    "Variable that holds whether last position was a ")

  (defvar rasmus/ob-header-symbol ?☰
    "Symbol used for babel headers")

  (defun rasmus/org-prettify-src--update ()
    (let ((case-fold-search t)
          (re "^[ \t]*#\\+begin_src[ \t]+[^ \f\t\n\r\v]+[ \t]*")
          found)
      (save-excursion
        (goto-char (point-min))
        (while (re-search-forward re nil t)
          (goto-char (match-end 0))
          (let ((args (org-trim
                       (buffer-substring-no-properties (point)
                                                       (line-end-position)))))
            (when (org-string-nw-p args)
              (let ((new-cell (cons args rasmus/ob-header-symbol)))
                (cl-pushnew new-cell prettify-symbols-alist :test #'equal)
                (cl-pushnew new-cell found :test #'equal)))))
        (setq prettify-symbols-alist
              (cl-set-difference prettify-symbols-alist
                                 (cl-set-difference
                                  (cl-remove-if-not
                                   (lambda (elm)
                                     (eq (cdr elm) rasmus/ob-header-symbol))
                                   prettify-symbols-alist)
                                  found :test #'equal)))
        ;; Clean up old font-lock-keywords.
        (font-lock-remove-keywords nil prettify-symbols--keywords)
        (setq prettify-symbols--keywords (prettify-symbols--make-keywords))
        (font-lock-add-keywords nil prettify-symbols--keywords)
        (while (re-search-forward re nil t)
          (font-lock-flush (line-beginning-position) (line-end-position))))))

  (defun rasmus/org-prettify-src ()
    "Hide src options via `prettify-symbols-mode'.

  `prettify-symbols-mode' is used because it has uncollpasing. It's
  may not be efficient."
    (let* ((case-fold-search t)
           (at-src-block (save-excursion
                           (beginning-of-line)
                           (looking-at "^[ \t]*#\\+begin_src[ \t]+[^ \f\t\n\r\v]+[ \t]*"))))
      ;; Test if we moved out of a block.
      (when (or (and rasmus/org-at-src-begin
                     (not at-src-block))
                ;; File was just opened.
                (eq rasmus/org-at-src-begin -1))
        (rasmus/org-prettify-src--update))
      ;; Remove composition if at line; doesn't work properly.
      ;; (when at-src-block
      ;;   (with-silent-modifications
      ;;     (remove-text-properties (match-end 0)
      ;;                             (1+ (line-end-position))
      ;;                             '(composition))))
      (setq rasmus/org-at-src-begin at-src-block)))

  (defun rasmus/org-prettify-symbols ()
    (mapc (apply-partially 'add-to-list 'prettify-symbols-alist)
          (cl-reduce 'append
                     (mapcar (lambda (x) (list x (cons (upcase (car x)) (cdr x))))
                             `(("#+begin_src" . ?✎) ;; ➤ 🖝 ➟ ➤ ✎
                               ("#+end_src"   . ?□) ;; ⏹
                               ("#+header:" . ,rasmus/ob-header-symbol)
                               ("#+begin_quote" . ?»)
                               ("#+end_quote" . ?«)))))
    (turn-on-prettify-symbols-mode)
    (add-hook 'post-command-hook 'rasmus/org-prettify-src t t))
  (add-hook 'org-mode-hook #'rasmus/org-prettify-symbols))
rasmus
fonte