Existe um yasnippet produzindo um comentário doxygen pré-preenchido?

10

Para a seguinte função C ++:

bool importantStuff(double a, double b);

Ele deve gerar o seguinte snippet, talvez sem as tags:

/**
 * <Insert description of importantStuff>
 *
 * @param a <Insert description of a>
 * @param b <Insert description of b>
 * @return <Insert description of the return value>
 */

Eu olhei em volta da rede, mas o mais próximo que cheguei de uma resposta é essa antiga pergunta do SO, em que a resposta depende do modo doxymacs que não é mais mantido.

yasnippet c++ Rovanion
fonte
Eu acho que c-sharp-modetem algo que faz isso.
Erikstokes
Deseja fazer isso para novas funções ou funções existentes?
itsjeyd
Ao fazer a pergunta, eu estava pensando sobre o comentário doxygen sendo gerado a partir da assinatura da função.
Rovanion

Respostas:

4

Eu uso o seguinte, que é um mashup do doxymacs padrão e o semântico do abo-abo já mencionado como resposta - isso requer apenas semântica e yasnippet. Isso preenche um pouco mais os espaços reservados do yasnippet com informações relevantes, em comparação com a versão do abo-abo também.


# -*- mode: snippet -*-
# name: dox
# key: dox
# type: command
# --
(unless (and (fboundp 'semantic-current-tag)
             semantic-mode)
  (error "Semantic required to use dox snippet"))
(let ((tag (senator-next-tag)))
  (while (or (null tag)
             (not (semantic-tag-of-class-p tag 'function)))
    (setq tag (senator-next-tag)))
  (let* ((name (semantic-tag-name tag))
         (attrs (semantic-tag-attributes tag))
         (args (plist-get attrs :arguments))
         (return-name (plist-get attrs :type))
         (idx 1))
    (if (listp return-name)
      (setq return-name (car return-name)))
    (yas/expand-snippet
     (format
      "/**
* @brief ${1:%s}
*
%s
%s*/
"
      name
      (mapconcat
       (lambda (x)
         (format "* @param %s ${%d:Description of %s}"
                 (car x) (incf idx) (car x)))
       args
       "\n")
      (if (and return-name (not (string-equal "void" return-name)))
          (format " * @return ${%d:%s}\n" (incf idx) return-name)
        "")))))
alexmurray
fonte
Essa solução funciona absolutamente, mas ter que esperar pelo modo semântico para percorrer todo o código necessário é um pouco complicado. Eu também tive o emacs ficando preso em loops infinitos se eu escrever dox <tab> antes de uma variável. Mas não se pode ter tudo neste mundo: D
Rovanion
esta deve ser considerados mais elevada do que a de cima, uma vez que é mais rica do que MOO-doxygen
Alejandro Erickson
3

Acabei de adicionar esse recurso ao function-args .

Aqui está o código, se você estiver interessado. Está usando o CEDET:

(defun moo-doxygen ()
  "Generate a doxygen yasnippet and expand it with `aya-expand'.
The point should be on the top-level function name."
  (interactive)
  (move-beginning-of-line nil)
  (let ((tag (semantic-current-tag)))
    (unless (semantic-tag-of-class-p tag 'function)
      (error "Expected function, got %S" tag))
    (let* ((name (semantic-tag-name tag))
           (attrs (semantic-tag-attributes tag))
           (args (plist-get attrs :arguments))
           (ord 1))
      (setq aya-current
            (format
             "/**
* $1
*
%s
* @return $%d
*/
"
             (mapconcat
              (lambda (x)
                (format "* @param %s $%d"
                        (car x) (incf ord)))
              args
              "\n")
             (incf ord)))
      (aya-expand))))

Você também precisa do yasnippet automático . Ambos os pacotes estão disponíveis no MELPA.

abo-abo
fonte