Como herdo do prog-mode, enquanto ainda suporta o emacsen mais antigo?

Estou escrevendo um modo principal para uma linguagem de programação, mas quero oferecer suporte a versões mais antigas do Emacs. prog-modeé relativamente novo. Quero herdar de prog-modese estiver definido, mas ainda assim fazer algo sensato.

Qual é a melhor abordagem? Devo defalias prog-modeno Emacsen mais antigo, ou isso interferirá em outros modos se eles fizerem a mesma coisa?

À custa de uma ligação extra de símbolo de nível superior, há uma solução muito elegante que evita repetir o define-derived-modeformulário:

(defalias 'my-fancy-parent-mode
  (if (fboundp 'prog-mode) 'prog-mode 'fundamental-mode))

(define-derived-mode my-fancy-mode my-fancy-parent-mode
   ...)

Funciona bem em qualquer Emacs> = 23. Eu vim com isso há haml-modealguns anos atrás, o IIRC, e parece que ele se espalhou de lá para vários outros modos principais. A principal coisa que a define-derived-modemacro faz com o símbolo do modo pai é gerar um código que chama sua função: nesse sentido, defaliastorna a nova variável exatamente equivalente à função com alias.

Uma ressalva é que isso pode confundir derived-mode-p, portanto, o código que verifica se seu modo é derivado prog-modepode não funcionar corretamente. Na prática, não encontrei nenhum problema: é mais comum o uso desse código prog-mode-hook, que ainda é executado.

(Como Jorgen aponta nos comentários, define-derived-modetambém usa a mode-classpropriedade do símbolo do modo pai e defaliasnão a copia. No momento da redação, esta propriedade parece ser usada apenasspecial-mode .)

Atualização: hoje em dia eu simplesmente sugeriria exigir pelo menos o Emacs 24, já que versões mais antigas são obsoletas há muito tempo.

tl; dr: Use ife sua própria função init:

(if (fboundp 'prog-mode)
    (define-derived-mode your-cool-mode prog-mode "Cool"
      "Docstring"
      (your-cool--init))
  (define-derived-mode your-cool-mode nil "Cool"
    "Docstring"
    (your-cool--init)))

Em seguida, faça toda a inicialização do modo em your-cool-init.

Explicação mais longa:

O problema é que a maneira oficial de escrever um modo principal derivado é usar a define-derived-modemacro:

(define-derived-mode your-cool-mode prog-mode ...)

No Emacsen mais antigo (pré-24), isso quebra quando prog-mode. E você não pode usá (if (fboundp 'prog-mode) ...)-lo porque a macro espera um símbolo literal e o citará na expansão.

define-derived-modeusa o pai de várias maneiras. Você precisaria copiar todos aqueles em sua própria definição de modo para usá-los, e isso é tedioso e propenso a erros.

Portanto, a única maneira é usar duas define-derived-modeinstruções diferentes , dependendo da existência prog-modeou não. Isso deixa você com o problema de escrever seu código de inicialização duas vezes. O que é obviamente ruim, então você extrai isso para sua própria função, conforme descrito acima.

(É claro que a melhor solução é largar o suporte para 23.xe usar o escopo lexical. Mas acho que você já considerou e largou essa opção. :-))

Eu acho que testar usando fboundpfaz mais sentido.

(if (fboundp 'prog-mode)
    ...
   ...)

Você pode definir uma macro de wrapper para define-derived-modeavaliar seus argumentos.

(defmacro define-derived-mode* (child parent name &optional docstring &rest body)
  (macroexpand `(define-derived-mode ,(eval child) ,(eval parent) ,(eval name)
                                     ,(eval docstring) . ,body)))
(define-derived-mode* 'toy-mode
  (if (fboundp 'prog-mode) 'prog-mode 'fundamental-mode)
  "Toy"
  "Major mode for my favorite toy language"
  (toy-mode-setup))

(Aviso: apenas minimamente testado.)