Como posso sair do ediff imediatamente sem precisar digitar 'y'

Quando parei de falar, qperguntei se realmente queria sair. Prefiro desistir imediatamente. Não há nada óbvio na personalização . Há uma solução aqui que parece funcionar redefinindo a qchave, mas não tenho certeza dos detalhes de como a função funciona. Qual é a maneira mais simples de sair para realmente significar sair?

Você pode aconselhá ediff-quit-lo para que ele se reconecte dinamicamente y-or-n-pa uma função que retorne t.

(defun disable-y-or-n-p (orig-fun &rest args)
  (cl-letf (((symbol-function 'y-or-n-p) (lambda (prompt) t)))
    (apply orig-fun args)))

(advice-add 'ediff-quit :around #'disable-y-or-n-p)

Isso é mais robusto para alterações upstream do que redefinir ediff-quit.

Infelizmente acho que você precisa religar q ou ajustar a fonte de ediff-quit. Como é evidente na fonte do ediff-quitprompt, sempre acontece.

(defun ediff-quit (reverse-default-keep-variants)
  "Finish an Ediff session and exit Ediff.
Unselects the selected difference, if any, restores the read-only and modified
flags of the compared file buffers, kills Ediff buffers for this session
\(but not buffers A, B, C\).

If `ediff-keep-variants' is nil, the user will be asked whether the buffers
containing the variants should be removed \(if they haven't been modified\).
If it is t, they will be preserved unconditionally.  A prefix argument,
temporarily reverses the meaning of this variable."
  (interactive "P")
  (ediff-barf-if-not-control-buffer)
  (let ((ctl-buf (current-buffer))
    (ctl-frm (selected-frame))
    (minibuffer-auto-raise t))
    (if (y-or-n-p (format "Quit this Ediff session%s? "
              (if (ediff-buffer-live-p ediff-meta-buffer)
                  " & show containing session group" "")))
    (progn
      (message "")
      (set-buffer ctl-buf)
      (ediff-really-quit reverse-default-keep-variants))
      (select-frame ctl-frm)
      (raise-frame ctl-frm)
      (message ""))))

Sugiro redefinir o ediff-quitseu .emacse enviar um patch para a fonte, adicionando uma variável de personalização.

Lembre-se de que a fonte de implementação no emacs está sempre a algumas teclas de distância. Presumindo que as fontes elisp estejam instaladas, digite C-h f, digite o nome da função e siga o link para onde está definido.

Eu uso a seguinte religação de q em ediff. Se qualquer um dos buffers for modificado, ele perguntará se eles devem ser salvos e simplesmente será encerrado. Se nenhum buffer for modificado, ele será encerrado.

(add-hook 'ediff-startup-hook
          (lambda ()
            (local-set-key (kbd"q") 'my-ediff-quit)))

(defun my-ediff-quit ()
  "If any of the ediff buffers have been modified, ask if changes
should be saved. Then quit ediff normally, without asking for
confirmation"
  (interactive)
  (ediff-barf-if-not-control-buffer)
  (let* ((buf-a ediff-buffer-A)
         (buf-b ediff-buffer-B)
         (buf-c ediff-buffer-C)
         (ctl-buf (current-buffer))
         (modified (remove-if-not 'buffer-modified-p
                                  (list buf-a buf-b buf-c))))
    (let ((save (if modified (yes-or-no-p "Save changes?")nil)))
      (loop for buf in modified do
            (progn
              (set-buffer buf)
              (if save
                  (save-buffer)
                (set-buffer-modified-p nil))))
      (set-buffer ctl-buf)
      (ediff-really-quit nil))))