Como obtenho o resultado de um comando em uma variável no windows?

Eu estou procurando obter o resultado de um comando como uma variável em um script em lotes do Windows (veja como obter o resultado de um comando no bash para o equivalente de script do bash). É preferível uma solução que funcione em um arquivo .bat, mas outras soluções comuns de script do Windows também são bem-vindas.

Se você precisar capturar toda a saída do comando, poderá usar um lote como este:

@ECHO OFF
IF NOT "%1"=="" GOTO ADDV
SET VAR=
FOR /F %%I IN ('DIR *.TXT /B /O:D') DO CALL %0 %%I
SET VAR
GOTO END

:ADDV
SET VAR=%VAR%!%1

:END

Todas as linhas de saída são armazenadas em VAR separadas por "!".

@ John: existe algum uso prático para isso? Eu acho que você deve assistir ao PowerShell ou qualquer outra linguagem de programação capaz de executar tarefas de script facilmente (Python, Perl, PHP, Ruby)

O humilde para o comando acumulou algumas capacidades interessantes ao longo dos anos:

D:\> FOR /F "delims=" %i IN ('date /t') DO set today=%i
D:\> echo %today%
Sat 20/09/2008

Observe que "delims=" substitui o espaço padrão e os delimitadores de tabulação para que a saída do comando date seja devorada ao mesmo tempo.

Para capturar a saída de várias linhas, ainda pode ser essencialmente uma linha (usando a variável lf como delimitador na variável resultante):

REM NB:in a batch file, need to use %%i not %i
setlocal EnableDelayedExpansion
SET lf=-
FOR /F "delims=" %%i IN ('dir \ /b') DO if ("!out!"=="") (set out=%%i) else (set out=!out!%lf%%%i)
ECHO %out%

Para capturar uma expressão canalizada, use ^|:

FOR /F "delims=" %%i IN ('svn info . ^| findstr "Root:"') DO set "URL=%%i"

Para obter o diretório atual, você pode usar isto:

CD > tmpFile
SET /p myvar= < tmpFile
DEL tmpFile
echo test: %myvar%

Ele está usando um arquivo temporário, portanto, não é o mais bonito, mas certamente funciona! 'CD' coloca o diretório atual em 'tmpFile', 'SET' carrega o conteúdo de tmpFile.

Aqui está uma solução para várias linhas com "array":

@echo off

rem ---------
rem Obtain line numbers from the file
rem ---------

rem This is the file that is being read: You can replace this with %1 for dynamic behaviour or replace it with some command like the first example i gave with the 'CD' command.
set _readfile=test.txt

for /f "usebackq tokens=2 delims=:" %%a in (`find /c /v "" %_readfile%`) do set _max=%%a
set /a _max+=1
set _i=0
set _filename=temp.dat

rem ---------
rem Make the list
rem ---------

:makeList
find /n /v "" %_readfile% >%_filename%

rem ---------
rem Read the list
rem ---------

:readList
if %_i%==%_max% goto printList

rem ---------
rem Read the lines into the array
rem ---------
for /f "usebackq delims=] tokens=2" %%a in (`findstr /r "\[%_i%]" %_filename%`) do set _data%_i%=%%a
set /a _i+=1
goto readList

:printList
del %_filename%
set _i=1
:printMore
if %_i%==%_max% goto finished
set _data%_i%
set /a _i+=1
goto printMore

:finished

Mas você pode considerar mudar para outro shell mais poderoso ou criar um aplicativo para esse material. Está ampliando bastante as possibilidades dos arquivos em lote.

você precisa usar o SETcomando com parâmetro /Pe direcionar sua saída para ele. Por exemplo, consulte http://www.ss64.com/nt/set.html . Funcionará para CMD, não tenho certeza sobre arquivos .BAT

De um comentário a este post:

Esse link tem o comando " Set /P _MyVar=<MyFilename.txt" que diz que será definido _MyVarpara a primeira linha de MyFilename.txt. Isso pode ser usado como " myCmd > tmp.txt" com " set /P myVar=<tmp.txt". Mas ele só obterá a primeira linha da saída, nem toda a saída

Exemplo para definir na variável de ambiente "V" o arquivo mais recente

FOR /F %I IN ('DIR *.* /O:D /B') DO SET V=%I

em um arquivo em lotes, é necessário usar o prefixo duplo na variável de loop:

FOR /F %%I IN ('DIR *.* /O:D /B') DO SET V=%%I

Basta usar o resultado do FORcomando. Por exemplo (dentro de um arquivo em lotes):

for /F "delims=" %%I in ('dir /b /a-d /od FILESA*') do (echo %%I)

Você pode usar %%Io valor que deseja. Assim como este: %%I.

E de antemão %%Inão possui espaços ou caracteres CR e pode ser usado para comparações !!

Se você está procurando a solução fornecida em Usando o resultado de um comando como argumento no bash?

então aqui está o código:

@echo off
if not "%1"=="" goto get_basename_pwd
for /f "delims=X" %%i in ('cd') do call %0 %%i
for /f "delims=X" %%i in ('dir /o:d /b') do echo %%i>>%filename%.txt
goto end

:get_basename_pwd
set filename=%~n1

:end

• Isso se chamará com o resultado do comando CD, o mesmo que pwd.
• A extração de string nos parâmetros retornará o nome do arquivo / pasta.
• Obtenha o conteúdo desta pasta e acrescente ao nome do arquivo.txt

[Créditos] : Obrigado a todas as outras respostas e algumas pesquisas na página de comandos do Windows XP .

@echo off

ver | find "6.1." > nul
if %ERRORLEVEL% == 0 (
echo Win7
for /f "delims=" %%a in ('DIR "C:\Program Files\Microsoft Office\*Outlook.EXE" /B /P /S') do call set findoutlook=%%a
%findoutlook%
)

ver | find "5.1." > nul
if %ERRORLEVEL% == 0 (
echo WinXP
for /f "delims=" %%a in ('DIR "C:\Program Files\Microsoft Office\*Outlook.EXE" /B /P /S') do call set findoutlook=%%a
%findoutlook%
)
echo Outlook dir:  %findoutlook%
"%findoutlook%"

Gostaria de acrescentar um comentário às soluções acima:

Todas essas sintaxes funcionam perfeitamente bem se o seu comando for encontrado no caminho ou se o comando for um cmdpath SEM ESPAÇOS OU PERSONAGENS ESPECIAIS.

Mas, se você tentar usar um comando executável localizado em uma pasta cujo caminho contenha caracteres especiais, será necessário colocar o caminho do comando entre aspas duplas (") e a sintaxe FOR / F não funcionará.

Exemplos:

$ for /f "tokens=* USEBACKQ" %f in (
    `""F:\GLW7\Distrib\System\Shells and scripting\f2ko.de\folderbrowse.exe"" Hello '"F:\GLW7\Distrib\System\Shells and scripting"'`
) do echo %f
The filename, directory name, or volume label syntax is incorrect.

ou

$ for /f "tokens=* USEBACKQ" %f in (
      `"F:\GLW7\Distrib\System\Shells and scripting\f2ko.de\folderbrowse.exe" "Hello World" "F:\GLW7\Distrib\System\Shells and scripting"`
) do echo %f
'F:\GLW7\Distrib\System\Shells' is not recognized as an internal or external command, operable program or batch file.

ou

`$ for /f "tokens=* USEBACKQ" %f in (
     `""F:\GLW7\Distrib\System\Shells and scripting\f2ko.de\folderbrowse.exe"" "Hello World" "F:\GLW7\Distrib\System\Shells and scripting"`
) do echo %f
'"F:\GLW7\Distrib\System\Shells and scripting\f2ko.de\folderbrowse.exe"" "Hello' is not recognized as an internal or external command, operable program or batch file.

Nesse caso, a única solução que encontrei para usar um comando e armazenar seu resultado em uma variável é definir (temporariamente) o diretório padrão como o próprio comando:

pushd "%~d0%~p0"
FOR /F "tokens=* USEBACKQ" %%F IN (
    `FOLDERBROWSE "Hello world!" "F:\GLW7\Distrib\System\Layouts (print,display...)"`
) DO (SET MyFolder=%%F)
popd
echo My selected folder: %MyFolder%

O resultado está correto:

My selected folder: F:\GLW7\Distrib\System\OS install, recovery, VM\
Press any key to continue . . .

Obviamente, no exemplo acima, presumo que meu script em lote esteja localizado na mesma pasta que a do meu comando executável, para que eu possa usar a sintaxe "% ~ d0% ~ p0". Se esse não for o seu caso, você precisará encontrar uma maneira de localizar o caminho do comando e alterar o diretório padrão para o caminho.

NB: Para quem se pergunta, o exemplo de comando usado aqui (para selecionar uma pasta) é FOLDERBROWSE.EXE. Encontrei-o no site f2ko.de ( http://f2ko.de/en/cmd.php ).

Se alguém tiver uma solução melhor para esse tipo de comando acessível por um caminho complexo, ficarei muito feliz em ouvi-lo.

Gilles

Você pode capturar toda a saída em uma variável, mas as linhas serão separadas por um caractere de sua escolha (# no exemplo abaixo) em vez de um CR-LF real.

@echo off
setlocal EnableDelayedExpansion
for /f "delims=" %%i in ('dir /b') do (
    if "!DIR!"=="" (set DIR=%%i) else (set DIR=!DIR!#%%i)
)
echo directory contains:
echo %DIR%

Segunda versão, se você precisar imprimir o conteúdo linha por linha. Isso tira vantagem do fato de que não haverá linhas de saída duplicadas de "dir / b", portanto, pode não funcionar no caso geral.

@echo off
setlocal EnableDelayedExpansion
set count=0
for /f "delims=" %%i in ('dir /b') do (
    if "!DIR!"=="" (set DIR=%%i) else (set DIR=!DIR!#%%i)
    set /a count = !count! + 1
)

echo directory contains:
echo %DIR%

for /l %%c in (1,1,%count%) do (
    for /f "delims=#" %%i in ("!DIR!") do (
        echo %%i
        set DIR=!DIR:%%i=!
    )
)

@echo off
setlocal EnableDelayedExpansion
FOR /F "tokens=1 delims= " %%i IN ('echo hola') DO (
    set TXT=%%i
)
echo 'TXT: %TXT%'

o resultado é 'TXT: hola'

Você deve usar o forcomando, aqui está um exemplo:

@echo off
rem Commands go here
exit /b
:output
for /f "tokens=* useback" %%a in (`%~1`) do set "output=%%a"

e você pode usar, call :output "Command goes here"então a saída estará na %output%variável

Nota: Se você tiver uma saída de comando que é multilinha, esta ferramenta fará seta saída para a última linha do seu comando de multilinha.

Consulte este http://technet.microsoft.com/en-us/library/bb490982.aspx, que explica o que você pode fazer com a saída do comando.