Meça o tempo necessário para executar uma consulta t-sql

Eu tenho duas consultas t-sql usando o SqlServer 2005. Como posso medir quanto tempo leva para cada uma ser executada?

Usar o cronômetro não é suficiente.

Uma abordagem simplista para medir o "tempo decorrido" entre os eventos é apenas pegar a data e hora atuais.

No SQL Server Management Studio

SELECT GETDATE();
SELECT /* query one */ 1 ;
SELECT GETDATE();
SELECT /* query two */ 2 ; 
SELECT GETDATE(); 

Para calcular os tempos decorridos, você pode capturar esses valores de data em variáveis ​​e usar a função DATEDIFF:

DECLARE @t1 DATETIME;
DECLARE @t2 DATETIME;

SET @t1 = GETDATE();
SELECT /* query one */ 1 ;
SET @t2 = GETDATE();
SELECT DATEDIFF(millisecond,@t1,@t2) AS elapsed_ms;

SET @t1 = GETDATE();
SELECT /* query two */ 2 ;
SET @t2 = GETDATE();
SELECT DATEDIFF(millisecond,@t1,@t2) AS elapsed_ms;

Essa é apenas uma abordagem. Você também pode obter tempos decorridos para consultas usando o SQL Profiler.

Se você deseja uma medida mais precisa do que a resposta acima:

set statistics time on 

-- Query 1 goes here

-- Query 2 goes here

set statistics time off

Os resultados estarão na janela Mensagens .

Atualização (29/07/2015):

Por solicitação popular, escrevi um trecho de código que você pode usar para cronometrar a execução de um procedimento armazenado inteiro, em vez de seus componentes. Embora isso retorne apenas o tempo gasto na última execução, há estatísticas adicionais retornadas sys.dm_exec_procedure_statsque também podem ter valor:

-- Use the last_elapsed_time from sys.dm_exec_procedure_stats
-- to time an entire stored procedure.

-- Set the following variables to the name of the stored proc
-- for which which you would like run duration info
DECLARE @DbName NVARCHAR(128);
DECLARE @SchemaName SYSNAME;
DECLARE @ProcName SYSNAME=N'TestProc';

SELECT CONVERT(TIME(3),DATEADD(ms,ROUND(last_elapsed_time/1000.0,0),0)) 
       AS LastExecutionTime
FROM sys.dm_exec_procedure_stats
WHERE OBJECT_NAME(object_id,database_id)=@ProcName AND
      (OBJECT_SCHEMA_NAME(object_id,database_id)=@SchemaName OR @SchemaName IS NULL) AND
      (DB_NAME(database_id)=@DbName OR @DbName IS NULL)

DECLARE @StartTime datetime
DECLARE @EndTime datetime
SELECT @StartTime=GETDATE() 

 -- Write Your Query


SELECT @EndTime=GETDATE()

--This will return execution time of your query
SELECT DATEDIFF(MS,@StartTime,@EndTime) AS [Duration in millisecs]

Você também pode ver esta solução

Outra maneira é usar um recurso interno do SQL Server chamado Client Statisticsacessível através de Menu> Consulta> Incluir Estatísticas do Cliente .

Você pode executar cada consulta na janela de consulta separada e comparar os resultados fornecidos na Client Statisticsguia ao lado da Messagesguia.

Por exemplo, na imagem abaixo, mostra que o tempo médio decorrido para obter a resposta do servidor para uma de minhas consultas é de 39 milissegundos.

Você pode ler todas as três maneiras de adquirir tempo de execução aqui . Pode ser necessário exibi-lo Estimated Execution Plan ctrlLpara uma investigação mais aprofundada sobre sua consulta.

melhor ainda, isso medirá a média de n iterações da sua consulta! Ótimo para uma leitura mais precisa.

declare @tTOTAL int = 0
declare @i integer = 0
declare @itrs integer = 100

while @i < @itrs
begin
declare @t0 datetime = GETDATE()

--your query here

declare @t1 datetime = GETDATE()

set @tTotal = @tTotal + DATEDIFF(MICROSECOND,@t0,@t1)

set @i = @i + 1
end

select @tTotal/@itrs

Clique no ícone Estatísticas para exibir e, em seguida, execute a consulta para obter os horários e saber a eficiência da sua consulta.