Groovy executando comandos de shell

O Groovy adiciona o executemétodo Stringpara facilitar a execução de shells;

println "ls".execute().text

mas se ocorrer um erro, não haverá saída resultante. Existe uma maneira fácil de obter o erro padrão e o padrão? (além de criar um monte de código para; criar dois encadeamentos para ler os dois fluxos de entrada e, em seguida, usar um fluxo pai para esperar que eles sejam concluídos e converter as seqüências novamente em texto?)

Seria bom ter algo parecido;

 def x = shellDo("ls /tmp/NoFile")
 println "out: ${x.out} err:${x.err}"

Ok, eu mesmo resolvi;

def sout = new StringBuilder(), serr = new StringBuilder()
def proc = 'ls /badDir'.execute()
proc.consumeProcessOutput(sout, serr)
proc.waitForOrKill(1000)
println "out> $sout err> $serr"

exibe:

out> err> ls: cannot access /badDir: No such file or directory

"ls".execute()retorna um Processobjeto e é por isso que "ls".execute().textfunciona. Você deve conseguir apenas ler o fluxo de erros para determinar se houve algum erro.

Existe um método extra em Processque lhe permitem passar um StringBufferpara recuperar o texto: consumeProcessErrorStream(StringBuffer error).

Exemplo:

def proc = "ls".execute()
def b = new StringBuffer()
proc.consumeProcessErrorStream(b)

println proc.text
println b.toString()

// a wrapper closure around executing a string                                  
// can take either a string or a list of strings (for arguments with spaces)    
// prints all output, complains and halts on error                              
def runCommand = { strList ->
  assert ( strList instanceof String ||
           ( strList instanceof List && strList.each{ it instanceof String } ) \
)
  def proc = strList.execute()
  proc.in.eachLine { line -> println line }
  proc.out.close()
  proc.waitFor()

  print "[INFO] ( "
  if(strList instanceof List) {
    strList.each { print "${it} " }
  } else {
    print strList
  }
  println " )"

  if (proc.exitValue()) {
    println "gave the following error: "
    println "[ERROR] ${proc.getErrorStream()}"
  }
  assert !proc.exitValue()
}

Acho isso mais idiomático:

def proc = "ls foo.txt doesnotexist.txt".execute()
assert proc.in.text == "foo.txt\n"
assert proc.err.text == "ls: doesnotexist.txt: No such file or directory\n"

Como outro post menciona, essas chamadas estão bloqueando, mas como queremos trabalhar com a saída, isso pode ser necessário.

Para adicionar mais uma informação importante às respostas fornecidas acima -

Para um processo

def proc = command.execute();

sempre tente usar

def outputStream = new StringBuffer();
proc.waitForProcessOutput(outputStream, System.err)
//proc.waitForProcessOutput(System.out, System.err)

ao invés de

def output = proc.in.text;

capturar as saídas após a execução de comandos no groovy, pois a última é uma chamada de bloqueio ( questão SO por motivo ).

def exec = { encoding, execPath, execStr, execCommands ->

def outputCatcher = new ByteArrayOutputStream()
def errorCatcher = new ByteArrayOutputStream()

def proc = execStr.execute(null, new File(execPath))
def inputCatcher = proc.outputStream

execCommands.each { cm ->
    inputCatcher.write(cm.getBytes(encoding))
    inputCatcher.flush()
}

proc.consumeProcessOutput(outputCatcher, errorCatcher)
proc.waitFor()

return [new String(outputCatcher.toByteArray(), encoding), new String(errorCatcher.toByteArray(), encoding)]

}

def out = exec("cp866", "C:\\Test", "cmd", ["cd..\n", "dir\n", "exit\n"])

println "OUT:\n" + out[0]
println "ERR:\n" + out[1]

command = "ls *"

def execute_state=sh(returnStdout: true, script: command)

mas se a falha do comando, o processo será encerrado