Inno Setup: Como desinstalar automaticamente a versão anterior instalada?

Estou usando o Inno Setup para criar um instalador.

Quero que o instalador desinstale automaticamente a versão anterior instalada, em vez de substituí-la. Como eu posso fazer isso?

Você deve ser capaz de ler a string de desinstalação do registro, dado o AppId (ou seja, o valor usado AppIDna [Setup]seção-). Ele pode ser encontrado em Software\Microsoft\Windows\CurrentVersion\Uninstall\{AppId}\(pode ser HKLMou HKCU, então é melhor verificar ambos), onde {AppId}deve ser substituído pelo valor real que você usou. Procure os valores UninstallStringou QuietUninstallStringe use a Execfunção para executá-los a partir de sua InitializeSetup()função de evento.

Atualização: solução alternativa não funcional removida usando uma [Run]entrada -section com {uninstallexe}- graças a todos os comentadores que apontaram isso!

Eu usei o seguinte. Não tenho certeza se é a maneira mais simples de fazer isso, mas funciona.

Este usa o {#emit SetupSetting("AppId")}que depende do pré-processador Inno Setup. Se você não usar isso, recorte e cole o ID do aplicativo diretamente.

[Code]

{ ///////////////////////////////////////////////////////////////////// }
function GetUninstallString(): String;
var
  sUnInstPath: String;
  sUnInstallString: String;
begin
  sUnInstPath := ExpandConstant('Software\Microsoft\Windows\CurrentVersion\Uninstall\{#emit SetupSetting("AppId")}_is1');
  sUnInstallString := '';
  if not RegQueryStringValue(HKLM, sUnInstPath, 'UninstallString', sUnInstallString) then
    RegQueryStringValue(HKCU, sUnInstPath, 'UninstallString', sUnInstallString);
  Result := sUnInstallString;
end;


{ ///////////////////////////////////////////////////////////////////// }
function IsUpgrade(): Boolean;
begin
  Result := (GetUninstallString() <> '');
end;


{ ///////////////////////////////////////////////////////////////////// }
function UnInstallOldVersion(): Integer;
var
  sUnInstallString: String;
  iResultCode: Integer;
begin
{ Return Values: }
{ 1 - uninstall string is empty }
{ 2 - error executing the UnInstallString }
{ 3 - successfully executed the UnInstallString }

  { default return value }
  Result := 0;

  { get the uninstall string of the old app }
  sUnInstallString := GetUninstallString();
  if sUnInstallString <> '' then begin
    sUnInstallString := RemoveQuotes(sUnInstallString);
    if Exec(sUnInstallString, '/SILENT /NORESTART /SUPPRESSMSGBOXES','', SW_HIDE, ewWaitUntilTerminated, iResultCode) then
      Result := 3
    else
      Result := 2;
  end else
    Result := 1;
end;

{ ///////////////////////////////////////////////////////////////////// }
procedure CurStepChanged(CurStep: TSetupStep);
begin
  if (CurStep=ssInstall) then
  begin
    if (IsUpgrade()) then
    begin
      UnInstallOldVersion();
    end;
  end;
end;

Alternativas

Veja também esta postagem do blog "Amostra de script do Inno Setup para comparação de versões" que vai um passo adiante e lê o número da versão de qualquer versão instalada anteriormente e compara esse número de versão com o do pacote de instalação atual.

Se você "deseja apenas remover os ícones antigos" (porque os seus foram alterados / atualizados), você pode usar isto:

; attempt to remove previous versions' icons
[InstallDelete]
Type: filesandordirs; Name: {group}\*;

Isso é executado "no início da instalação", então basicamente remove os ícones antigos, e os novos ainda serão instalados lá depois que isso for concluído.

Eu apenas faço isso com cada instalação "caso algo tenha mudado" em relação ao ícone (tudo é reinstalado de qualquer maneira).

Ao usar o Inno Setup, não há razão para desinstalar uma versão anterior, a menos que essa versão tenha sido instalada por um programa de instalação diferente. Caso contrário, as atualizações são tratadas automaticamente.

A resposta fornecida por Craig McQueen é totalmente viável. Embora, eu adicionaria esses comentários:

• O {#emit SetupSetting("AppId")}código não funciona para mim, então apenas adiciono meu ID do aplicativo.
• Eu não queria executar meu programa de desinstalação porque tenho um arquivo de configuração INI armazenado na pasta AppData / que é removido pelo desinstalador e não quero que seja apagado ao instalar uma nova versão. Então, modifiquei um pouco o código fornecido por Craig McQueen para remover o diretório onde está instalado o programa, após recuperar seu caminho.

Portanto, em relação ao código de Craig McQueen, as mudanças são:

• Recupere a InstallLocationchave em vez da UninstallStringchave.
• Use a DelTreefunção em vez doExec(sUnInstallString, ...)

Para qualquer pessoa que use o GetUninstallString()sugerido acima para forçar uma desinstalação interna CurStepChanged()e tenha problemas de cache de disco, veja abaixo uma solução relacionada que realmente espera um pouco após a desinstalação para que o exe desinstalador seja excluído!

Problema de cache de disco com configuração inno?

Você pode executar um desinstalador na seção [código]. Você tem que descobrir como obter o caminho para o desinstalador existente. Para simplificar, quando instalo meus aplicativos, adiciono um valor de string de registro que aponta para a pasta que contém o desinstalador e apenas executo o desinstalador no retorno de chamada InitializeWizard.

Lembre-se de que os nomes dos desinstaladores de instalação do Inno estão todos no formato uninsnnn.exe, você precisa levar isso em consideração no seu código.

Eu editei o código do @Crain Mc-Queen, acho que este código é melhor porque não precisa ser modificado em outro projeto:

[Code]
function GetNumber(var temp: String): Integer;
var
  part: String;
  pos1: Integer;
begin
  if Length(temp) = 0 then
  begin
    Result := -1;
    Exit;
  end;
    pos1 := Pos('.', temp);
    if (pos1 = 0) then
    begin
      Result := StrToInt(temp);
    temp := '';
    end
    else
    begin
    part := Copy(temp, 1, pos1 - 1);
      temp := Copy(temp, pos1 + 1, Length(temp));
      Result := StrToInt(part);
    end;
end;

function CompareInner(var temp1, temp2: String): Integer;
var
  num1, num2: Integer;
begin
    num1 := GetNumber(temp1);
  num2 := GetNumber(temp2);
  if (num1 = -1) or (num2 = -1) then
  begin
    Result := 0;
    Exit;
  end;
      if (num1 > num2) then
      begin
        Result := 1;
      end
      else if (num1 < num2) then
      begin
        Result := -1;
      end
      else
      begin
        Result := CompareInner(temp1, temp2);
      end;
end;

function CompareVersion(str1, str2: String): Integer;
var
  temp1, temp2: String;
begin
    temp1 := str1;
    temp2 := str2;
    Result := CompareInner(temp1, temp2);
end;

function InitializeSetup(): Boolean;
var
  oldVersion: String;
  uninstaller: String;
  ErrorCode: Integer;
  vCurID      :String;
  vCurAppName :String;
begin
  vCurID:= '{#SetupSetting("AppId")}';
  vCurAppName:= '{#SetupSetting("AppName")}';
  //remove first "{" of ID
  vCurID:= Copy(vCurID, 2, Length(vCurID) - 1);
  //
  if RegKeyExists(HKEY_LOCAL_MACHINE,
    'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\' + vCurID + '_is1') then
  begin
    RegQueryStringValue(HKEY_LOCAL_MACHINE,
      'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\' + vCurID + '_is1',
      'DisplayVersion', oldVersion);
    if (CompareVersion(oldVersion, '{#SetupSetting("AppVersion")}') < 0) then      
    begin
      if MsgBox('Version ' + oldVersion + ' of ' + vCurAppName + ' is already installed. Continue to use this old version?',
        mbConfirmation, MB_YESNO) = IDYES then
      begin
        Result := False;
      end
      else
      begin
          RegQueryStringValue(HKEY_LOCAL_MACHINE,
            'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\' + vCurID + '_is1',
            'UninstallString', uninstaller);
          ShellExec('runas', uninstaller, '/SILENT', '', SW_HIDE, ewWaitUntilTerminated, ErrorCode);
          Result := True;
      end;
    end
    else
    begin
      MsgBox('Version ' + oldVersion + ' of ' + vCurAppName + ' is already installed. This installer will exit.',
        mbInformation, MB_OK);
      Result := False;
    end;
  end
  else
  begin
    Result := True;
  end;
end;

Eu devo estar esquecendo alguma coisa. Os novos arquivos são copiados para o diretório de destino antes de ocorrer a remoção da instalação antiga. Em seguida, vem o desinstalador os exclui e remove o diretório.

Não use a seção [Run], mas o [UninstallRun]. De fato, os programas em [Executar] são executados após a instalação, causando a desinstalação do programa imediatamente após a instalação: - | Em vez disso, a seção [UninstallRun] é avaliada antes da instalação.

Siga este link: http://news.jrsoftware.org/news/innosetup/msg55323.html

Na função InitializeSetup (), você pode chamar "MSIEXEC / x {seu ID do programa}" após o prompt do usuário para desinstalar a versão antiga