Redirecionando a saída de dentro do arquivo de lote

Estou criando um arquivo em lote com alguns comandos simples para reunir informações de um sistema. O arquivo em lote contém comandos para obter a hora, informações de IP, usuários, etc.

Montei todos os comandos em um arquivo em lote e ele roda, mas gostaria que o arquivo em lote, quando executado, produzisse os resultados em um arquivo de texto (log). Existe um comando que posso adicionar ao lote que faria isso?

Lembre-se de que não quero executar o lote do cmd e, em seguida, redirecionar a saída; Quero redirecionar a saída de dentro do lote, se isso for possível.

A maneira simples e ingênua que é lenta porque abre e posiciona o ponteiro do arquivo para o fim do arquivo várias vezes.

@echo off
command1 >output.txt
command2 >>output.txt
...
commandN >>output.txt

Uma maneira melhor - mais fácil de escrever e mais rápida porque o arquivo é aberto e posicionado apenas uma vez.

@echo off
>output.txt (
  command1
  command2
  ...
  commandN
)

Outra maneira boa e rápida que só abre e posiciona o arquivo uma vez

@echo off
call :sub >output.txt
exit /b

:sub
command1
command2
...
commandN

Editar 2017-04-2020

De vez em quando, você pode querer gravar repetidamente em dois ou mais arquivos. Você também pode querer mensagens diferentes na tela. Ainda é possível fazer isso de forma eficiente redirecionando para identificadores indefinidos fora de um bloco ou sub-rotina entre parênteses e, em seguida, usar a &notação para referenciar os arquivos já abertos.

call :sub 9>File1.txt 8>File2.txt
exit /b

:sub
echo Screen message 1
>&9 File 1 message 1
>&8 File 2 message 1
echo Screen message 2
>&9 File 1 message 2
>&8 File 2 message 2
exit /b

Eu escolhi usar as alças 9 e 8 na ordem reversa porque dessa forma é mais provável que evite o redirecionamento permanente potencial devido a uma falha de design de implementação de redirecionamento da Microsoft ao executar vários redirecionamentos no mesmo comando. É altamente improvável, mas mesmo essa abordagem pode expor o bug se você tentar o suficiente. Se você realizar o redirecionamento, terá a garantia de evitar o problema.

3>File1.txt ( 4>File2.txt call :sub)
exit /b

:sub
etc.

se você deseja que os fluxos de saída e de erro sejam redirecionados

dir >> a.txt 2>&1

Eu sei que esta é uma postagem mais antiga, mas alguém vai topar com ela em uma pesquisa no Google e também parece que algumas perguntas que o OP fez nos comentários não foram abordadas especificamente. Além disso, vá com calma, pois esta é minha primeira resposta postada no SO. :)

Para redirecionar a saída para um arquivo usando um nome de arquivo gerado dinamicamente, minha abordagem go-to (leia-se: rápido e sujo) é a segunda solução oferecida por @dbenham. Então, por exemplo, este:

@echo off
> filename_prefix-%DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.log (
echo Your Name Here
echo Beginning Date/Time: %DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.log
REM do some stuff here
echo Your Name Here
echo Ending Date/Time: %DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.log
)

Irá criar um arquivo como o que você vê nesta imagem do arquivo no diretório de destino

Isso conterá esta saída:

Your Name Here
Beginning Date/Time: 2016-09-16_141048.log
Your Name Here
Ending Date/Time: 2016-09-16_141048.log

Lembre-se também de que essa solução depende da localidade, portanto, tome cuidado como / quando usá-la.

echo some output >"your logfile"

ou

(
 echo some output
 echo more output
)>"Your logfile"

deve preencher a conta.

Se você quiser APPENDa saída, use em >>vez de >. >irá iniciar um novo arquivo de log.

@echo off
>output.txt (
echo Checking your system infor, Please wating...

systeminfo | findstr /c:"Host Name" 
systeminfo | findstr /c:"Domain"

ipconfig /all | find "Physical Address" 

ipconfig | find "IPv4" 
ipconfig | find "Default Gateway"

)

@pause

Há um pequeno programa legal que você pode usar para redirecionar a saída para um arquivo e o console

some_command  ^|  TEE.BAT  [ -a ]  filename 

@ECHO OFF
:: Check Windows version
IF NOT "%OS%"=="Windows_NT" GOTO Syntax

:: Keep variables local
SETLOCAL

:: Check command line arguments
SET Append=0
IF /I [%1]==[-a] (
	SET Append=1
	SHIFT
)
IF     [%1]==[] GOTO Syntax
IF NOT [%2]==[] GOTO Syntax

:: Test for invalid wildcards
SET Counter=0
FOR /F %%A IN ('DIR /A /B %1 2^>NUL') DO CALL :Count "%%~fA"
IF %Counter% GTR 1 (
	SET Counter=
	GOTO Syntax
)

:: A valid filename seems to have been specified
SET File=%1

:: Check if a directory with the specified name exists
DIR /AD %File% >NUL 2>NUL
IF NOT ERRORLEVEL 1 (
	SET File=
	GOTO Syntax
)

:: Specify /Y switch for Windows 2000 / XP COPY command
SET Y=
VER | FIND "Windows NT" > NUL
IF ERRORLEVEL 1 SET Y=/Y

:: Flush existing file or create new one if -a wasn't specified
IF %Append%==0 (COPY %Y% NUL %File% > NUL 2>&1)

:: Actual TEE
FOR /F "tokens=1* delims=]" %%A IN ('FIND /N /V ""') DO (
	>  CON    ECHO.%%B
	>> %File% ECHO.%%B
)

:: Done
ENDLOCAL
GOTO:EOF

:Count
SET /A Counter += 1
SET File=%1
GOTO:EOF

:Syntax
ECHO.
ECHO Tee.bat,  Version 2.11a for Windows NT 4 / 2000 / XP
ECHO Display text on screen and redirect it to a file simultaneously
ECHO.
IF NOT "%OS%"=="Windows_NT" ECHO Usage:  some_command  ³  TEE.BAT  [ -a ]  filename
IF NOT "%OS%"=="Windows_NT" GOTO Skip
ECHO Usage:  some_command  ^|  TEE.BAT  [ -a ]  filename
:Skip
ECHO.
ECHO Where:  "some_command" is the command whose output should be redirected
ECHO         "filename"     is the file the output should be redirected to
ECHO         -a             appends the output of the command to the file,
ECHO                        rather than overwriting the file
ECHO.
ECHO Written by Rob van der Woude
ECHO http://www.robvanderwoude.com
ECHO Modified by Kees Couprie
ECHO http://kees.couprie.org
ECHO and Andrew Cameron

@echo OFF
[your command] >> [Your log file name].txt

Usei o comando acima no meu arquivo em lote e funcionou. No arquivo de log, mostra os resultados do meu comando.

Adicione estas duas linhas perto do topo do seu arquivo em lote, todos os stdout e stderr depois serão redirecionados para log.txt:

if not "%1"=="STDOUT_TO_FILE"  %0 STDOUT_TO_FILE %*  >log.txt 2>&1
shift /1

Isso pode falhar no caso de caracteres "tóxicos" na entrada. Considerar uma entrada como thisIsAnIn ^^^^ put é uma boa maneira de entender o que está acontecendo. Claro que existe uma regra que determina que uma string de entrada DEVE estar entre aspas duplas, mas tenho a sensação de que essa regra é válida apenas se o significado da entrada for um local em uma partição NTFS (talvez seja uma regra para URLs I não tenho a certeza). Mas não é uma regra para uma string de entrada arbitrária, é claro (é uma "boa prática", mas você não pode contar com ela).

Adicionar as seguintes linhas na parte inferior de seu arquivo em lote pegará tudo exatamente como exibido na janela CMD e exportará para um arquivo de texto:

powershell -c "$wshell = New-Object -ComObject wscript.shell; $wshell.SendKeys('^a')
powershell -c "$wshell = New-Object -ComObject wscript.shell; $wshell.SendKeys('^c')
powershell Get-Clipboard > MyLog.txt

Basicamente, ele seleciona tudo -> copiar para a área de transferência -> colar no arquivo de texto .