Como excluir vários buffers no Vim?

Supondo que eu tenha vários arquivos abertos como buffers no Vim. Os arquivos têm *.cpp, *.he alguns são *.xml. Eu quero fechar todos os arquivos XML com :bd *.xml. No entanto, o Vim não permite isso (E93: Mais de uma correspondência ...).

Há alguma maneira de fazer isso?

PS Eu sei que :bd file1 file2 file3funciona. Para que eu possa de algum modo avaliar *.xmla file1.xml file2.xml file3.xml?

Você pode usar <C-a>para concluir todas as correspondências. Portanto, se você digitar :bd *.xmle pressionar <C-a>, o vim concluirá o comando para :bd file1.xml file2.xml file3.xml.

:3,5bd[elete]   

Exclui o intervalo do buffer de 3 a 5.

Você também pode usar como alternativa:

    :.,$-bd[elete]    " to delete buffers from the current one to last but one
    :%bd[elete]       " to delete all buffers

Você pode usar isso.

:exe 'bd '. join(filter(map(copy(range(1, bufnr('$'))), 'bufname(v:val)'), 'v:val =~ "\.xml$"'), ' ')

Deve ser bastante fácil adicioná-lo a um comando.

function! s:BDExt(ext)
  let buffers = filter(range(1, bufnr('$')), 'buflisted(v:val) && bufname(v:val) =~ "\.'.a:ext.'$"')
  if empty(buffers) |throw "no *.".a:ext." buffer" | endif
  exe 'bd '.join(buffers, ' ')
endfunction

command! -nargs=1 BDExt :call s:BDExt(<f-args>)

Experimente o script abaixo. O exemplo é para "txt", altere-o conforme necessário, por exemplo, para "xml". Buffers modificados não são excluídos. Pressione \ bd para excluir os buffers.

map <Leader>bd :bufdo call <SID>DeleteBufferByExtension("txt")

function!  <SID>DeleteBufferByExtension(strExt)
   if (matchstr(bufname("%"), ".".a:strExt."$") == ".".a:strExt )
      if (! &modified)
         bd
      endif
   endif
endfunction

[Editar] Mesmo sem: bufdo (conforme solicitado por Luc Hermitte, veja o comentário abaixo)

map <Leader>bd :call <SID>DeleteBufferByExtension("txt")

function!  <SID>DeleteBufferByExtension(strExt)
   let s:bufNr = bufnr("$")
   while s:bufNr > 0
       if buflisted(s:bufNr)
           if (matchstr(bufname(s:bufNr), ".".a:strExt."$") == ".".a:strExt )
              if getbufvar(s:bufNr, '&modified') == 0
                 execute "bd ".s:bufNr
              endif
           endif
       endif
       let s:bufNr = s:bufNr-1
   endwhile
endfunction

Eu também precisava dessa funcionalidade o tempo todo. Esta é a solução que tenho no meu vimrc.

function! GetBufferList()
    return filter(range(1,bufnr('$')), 'buflisted(v:val)')
endfunction

function! GetMatchingBuffers(pattern)
    return filter(GetBufferList(), 'bufname(v:val) =~ a:pattern')
endfunction

function! WipeMatchingBuffers(pattern)
    let l:matchList = GetMatchingBuffers(a:pattern)

    let l:count = len(l:matchList)
    if l:count < 1
        echo 'No buffers found matching pattern ' . a:pattern
        return
    endif

    if l:count == 1
        let l:suffix = ''
    else
        let l:suffix = 's'
    endif

    exec 'bw ' . join(l:matchList, ' ')

    echo 'Wiped ' . l:count . ' buffer' . l:suffix . '.'
endfunction

command! -nargs=1 BW call WipeMatchingBuffers('<args>')

Agora, eu posso fazer :BW regex(por exemplo, :BW \.cpp$e limpar todos os buffers correspondentes que correspondam a esse padrão em seu nome de caminho.

Se você deseja excluir, em vez de limpar, é claro que pode substituir exec 'bw ' . join(l:matchList, ' ')porexec 'bd ' . join(l:matchList, ' ')

Muito simplesmente: use o :bd[elete]comando Por exemplo, :bd[elete] buf#1 buf#5 buf#3excluirá os buffers 1, 3 e 5.

TABsó irá completar automaticamente um arquivo para você a partir de Vim 7.4.282
uso <c-a>de autocomplete todos os arquivos.

Você pode apenas usar:

bd filetype

use apenas <c-a>para facilitar a conclusão de todos os arquivos abertos do tipo de arquivo especificado.

por exemplo, você tem 1.xml, 2.xml, 3.xml e 4.xml, você pode:

bd xml

então aperte <c-a>

O vim será preenchido automaticamente para você da seguinte maneira:

bd 1.xml 2.xml 3.xml 4.xml

você pode simplesmente pressionar enter para concluir o comando.

Se você fez alterações em um dos arquivos mencionados acima, lembre-se de fazer:

bd! xml