Como posso executar uma pesquisa de seqüência reversa no Excel sem usar o VBA?

Eu tenho uma planilha do Excel que contém uma lista de seqüências de caracteres. Cada string é composta de várias palavras, mas o número de palavras em cada string é diferente.

Usando funções internas do Excel (sem VBA), existe uma maneira de isolar a última palavra em cada string?

Exemplos:

  Você é classificado como humano? -> humano?
Negativo, eu sou um picolé de carne -> picolé
                  Aziz! Luz! -> Luz!

Este é testado e funciona (com base no post original de Brad):

=RIGHT(A1,LEN(A1)-FIND("|",SUBSTITUTE(A1," ","|",
     LEN(A1)-LEN(SUBSTITUTE(A1," ","")))))

Se suas strings originais pudessem conter um pipe "|" caractere, substitua os dois acima por outro caractere que não aparecerá na sua fonte. (Eu suspeito que o original de Brad estava quebrado porque um caractere não imprimível foi removido na tradução).

Bônus: Como funciona (da direita para a esquerda):

LEN(A1)-LEN(SUBSTITUTE(A1," ",""))- Contagem de espaços na cadeia original
SUBSTITUTE(A1," ","|", ... )- Substitui apenas a final espaço por a |
FIND("|", ... )- Encontra a posição absoluta da substituída |(que era o espaço final)
Right(A1,LEN(A1) - ... ))- Retorna todos os caracteres depois disso|

EDIT: para explicar o caso em que o texto de origem não contém espaços, adicione o seguinte ao início da fórmula:

=IF(ISERROR(FIND(" ",A1)),A1, ... )

fazendo a fórmula inteira agora:

=IF(ISERROR(FIND(" ",A1)),A1, RIGHT(A1,LEN(A1) - FIND("|",
    SUBSTITUTE(A1," ","|",LEN(A1)-LEN(SUBSTITUTE(A1," ",""))))))

Ou você pode usar a =IF(COUNTIF(A1,"* *")sintaxe da outra versão.

Quando a sequência original puder conter um espaço na última posição, adicione uma função de recorte ao contar todos os espaços: Tornando a função o seguinte:

=IF(ISERROR(FIND(" ",B2)),B2, RIGHT(B2,LEN(B2) - FIND("|",
    SUBSTITUTE(B2," ","|",LEN(TRIM(B2))-LEN(SUBSTITUTE(B2," ",""))))))

Esta é a técnica que usei com grande sucesso:

=TRIM(RIGHT(SUBSTITUTE(A1, " ", REPT(" ", 100)), 100))

Para obter a primeira palavra em uma string, mude de DIREITA para ESQUERDA

=TRIM(LEFT(SUBSTITUTE(A1, " ", REPT(" ", 100)), 100))

Além disso, substitua A1 pela célula que contém o texto.

Uma versão mais robusta da resposta de Jerry:

=TRIM(RIGHT(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))), LEN(TRIM(A1))))

Isso funciona independentemente do comprimento da string, espaços iniciais ou finais, ou qualquer outra coisa, e ainda é bem curto e simples.

Encontrei isso no google, testado no Excel 2003 e funciona para mim:

=IF(COUNTIF(A1,"* *"),RIGHT(A1,LEN(A1)-LOOKUP(LEN(A1),FIND(" ",A1,ROW(INDEX($A:$A,1,1):INDEX($A:$A,LEN(A1),1))))),A1)

[edit] Eu não tenho representante suficiente para comentar, então esse parece o melhor lugar ... A resposta de BradC também não funciona com espaços à direita ou células vazias ...
[2ª edição] na verdade, não funciona para palavras simples também ...

=RIGHT(TRIM(A1),LEN(TRIM(A1))-FIND(CHAR(7),SUBSTITUTE(" "&TRIM(A1)," ",CHAR(7),
LEN(TRIM(A1))-LEN(SUBSTITUTE(" "&TRIM(A1)," ",""))+1))+1)

Isso é muito robusto - funciona para frases sem espaços, espaços iniciais / finais, múltiplos espaços, vários espaços iniciais / finais ... e usei char (7) para o delimitador, em vez da barra vertical "|" apenas no caso de ser um item de texto desejado.

Isso é muito limpo e compacto e funciona bem.

{=RIGHT(A1,LEN(A1)-MAX(IF(MID(A1,ROW(1:999),1)=" ",ROW(1:999),0)))}

Ele não trava erros por nenhum espaço ou uma palavra, mas é fácil de adicionar.

Editar:
trata de espaços à direita, palavra única e cenários de células vazias. Eu não encontrei uma maneira de quebrá-lo.

{=RIGHT(TRIM(A1),LEN(TRIM(A1))-MAX(IF(MID(TRIM(A1),ROW($1:$999),1)=" ",ROW($1:$999),0)))}

=RIGHT(A1,LEN(A1)-FIND("`*`",SUBSTITUTE(A1," ","`*`",LEN(A1)-LEN(SUBSTITUTE(A1," ",""))))) 

Para adicionar às respostas de Jerry e Joe, se você deseja encontrar o texto ANTES da última palavra, pode usar:

=TRIM(LEFT(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))), LEN(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))))-LEN(TRIM(A1))))

Com 'Meu gatinho' em A1 resultaria em 'Meu gatinho' (onde Joe e Jerry's dariam 'gato'

Da mesma forma que Jerry e Joe isolam a última palavra, isso apenas coloca tudo à esquerda disso (depois apara)

Imagine que a corda possa ser revertida. Então é realmente fácil. Em vez de trabalhar na string:

"My little cat" (1)

você trabalha com

"tac elttil yM" (2)

Com =LEFT(A1;FIND(" ";A1)-1)em A2 você obtém "My"com (1) e "tac"com (2), que é invertido"cat" , a última palavra em (1).

Existem alguns VBAs ao redor para reverter uma string. Eu prefiro a função pública do VBA ReverseString.

Instale o descrito acima, como descrito. Depois, com sua string em A1, por exemplo, "My little cat"e esta função em A2:

=ReverseString(LEFT(ReverseString(A1);IF(ISERROR(FIND(" ";A1));
  LEN(A1);(FIND(" ";ReverseString(A1))-1))))

você verá "cat"na A2.

O método acima pressupõe que as palavras são separadas por espaços em branco. A IFcláusula é para células que contêm palavras únicas = sem espaços em branco na célula. Nota: TRIMe CLEANa sequência original também é útil. Em princípio, ele reverte toda a cadeia de caracteres de A1 e simplesmente encontra o primeiro espaço em branco na cadeia de reversão que fica ao lado da última palavra (invertida) (ou seja, "tac "). LEFTescolhe essa palavra e outra reversão de string reconstitui a ordem original da palavra ( " cat"). O -1no final doFIND instrução remove o espaço em branco.

A idéia é que é fácil extrair a primeira (!) Palavra em uma string com LEFTe FINDno primeiro espaço em branco. No entanto, para a última (!) Palavra, oRIGHT função é a escolha errada quando você tenta fazer isso porque, infelizmente, o FIND não possui um sinalizador para a direção em que você deseja analisar sua string.

Portanto, toda a cadeia é simplesmente revertida. LEFTe FINDtrabalhe normalmente, mas a cadeia extraída é invertida. Mas o dele não é grande coisa quando você sabe como reverter uma string. A primeira ReverseStringdeclaração na fórmula faz esse trabalho.

=LEFT(A1,FIND(IF(
 ISERROR(
  FIND("_",A1)
 ),A1,RIGHT(A1,
  LEN(A1)-FIND("~",
   SUBSTITUTE(A1,"_","~",
    LEN(A1)-LEN(SUBSTITUTE(A1,"_",""))
   )
  )
 )
),A1,1)-2)

Copie para uma coluna, selecione-a e HOME> Edição> Localizar e selecionar, Substituir:

Replace All.

Há um espaço após o asterisco.

Traduzi para o PT-BR, pois precisava disso também.

(Observe que mudei o espaço para \porque precisava do nome do arquivo apenas de cadeias de caminho.)

=SE(ÉERRO(PROCURAR("\",A1)),A1,DIREITA(A1,NÚM.CARACT(A1)-PROCURAR("|", SUBSTITUIR(A1,"\","|",NÚM.CARACT(A1)-NÚM.CARACT(SUBSTITUIR(A1,"\",""))))))

Outra maneira de conseguir isso é como abaixo

=IF(ISERROR(TRIM(MID(TRIM(D14),SEARCH("|",SUBSTITUTE(TRIM(D14)," ","|",LEN(TRIM(D14))-LEN(SUBSTITUTE(TRIM(D14)," ","")))),LEN(TRIM(D14))))),TRIM(D14),TRIM(MID(TRIM(D14),SEARCH("|",SUBSTITUTE(TRIM(D14)," ","|",LEN(TRIM(D14))-LEN(SUBSTITUTE(TRIM(D14)," ","")))),LEN(TRIM(D14)))))

Eu também tive uma tarefa como essa e, quando terminei, usando o método acima, ocorreu um novo método: Por que você não faz isso:

1. Inverta a string ("string one" se torna "eno gnirts").
2. Use o bom e velho Find (que é codificado para a esquerda para a direita).
3. Inverta-o em sequência legível novamente.

Como isso soa?