Obtendo resultado de SQL dinâmico em uma variável para sql-server

116

Executando SQL dinâmico da seguinte maneira em Procedimento Armazenado:

DECLARE @sqlCommand nvarchar(1000)
DECLARE @city varchar(75)
SET @city = 'London'
SET @sqlCommand = 'SELECT COUNT(*) FROM customers WHERE City = @city'
EXECUTE sp_executesql @sqlCommand, N'@city nvarchar(75)', @city = @city

Como utilizo o valor da coluna count (*) como valor de retorno no SP?

sql sql-server sql-server-2005 tsql dynamic-sql Peter Lindholm
fonte

202

DECLARE @sqlCommand nvarchar(1000)
DECLARE @city varchar(75)
declare @counts int
SET @city = 'New York'
SET @sqlCommand = 'SELECT @cnt=COUNT(*) FROM customers WHERE City = @city'
EXECUTE sp_executesql @sqlCommand, N'@city nvarchar(75),@cnt int OUTPUT', @city = @city, @cnt=@counts OUTPUT
select @counts as Counts

Sábio
fonte

4

+1: Você chegou antes de mim, precisa declarar uma variável e marcá-la como OUTPUT. Para obter mais informações e uma leitura recomendada para SQL Server dinâmico SQL, consulte A maldição e as bênçãos do SQL dinâmico

Pôneis OMG,

1

Obrigado. A palavra-chave OUTPUT em N '@ city nvarchar (75), @ cnt int OUTPUT' era o que estava faltando.

Peter Lindholm,

1

Não há solução que não exija a adição de uma variável de saída à instrução dinâmica ??

Tab Alleman

2

Você provavelmente já tentou fazer isso, mas suas especificações permitem que você faça isso?

DECLARE @city varchar(75)
DECLARE @count INT
SET @city = 'London'
SELECT @count = COUNT(*) FROM customers WHERE City = @city

Brad
fonte

2

versão dinâmica

    ALTER PROCEDURE [dbo].[ReseedTableIdentityCol](@p_table varchar(max))-- RETURNS int
    AS
    BEGIN
        -- Declare the return variable here
       DECLARE @sqlCommand nvarchar(1000)
       DECLARE @maxVal INT
       set @sqlCommand = 'SELECT @maxVal = ISNULL(max(ID),0)+1 from '+@p_table
       EXECUTE sp_executesql @sqlCommand, N'@maxVal int OUTPUT',@maxVal=@maxVal OUTPUT
       DBCC CHECKIDENT(@p_table, RESEED, @maxVal)
    END


exec dbo.ReseedTableIdentityCol @p_table='Junk'

Ab Bennett
fonte

0

DECLARE @sqlCommand nvarchar(1000)
DECLARE @city varchar(75)
DECLARE @cnt int
SET @city = 'London'
SET @sqlCommand = 'SELECT @cnt=COUNT(*) FROM customers WHERE City = @city'
EXECUTE sp_executesql @sqlCommand, N'@city nvarchar(75)', @city = @city
RETURN @cnt

CristiC
fonte

1

Acho que sua resposta foi cortada.

Sábado,

Msg 137, Must declare the scalar variable "@cnt". Msg 178 A RETURN statement with a return value cannot be used in this context.,. Um bom trabalho, mano))

it3xl

0

isso poderia ser uma solução?

declare @step2cmd nvarchar(200)
DECLARE @rcount NUMERIC(18,0)   
set @step2cmd = 'select count(*) from uat.ap.ztscm_protocollo' --+ @nometab
EXECUTE @rcount=sp_executesql @step2cmd
select @rcount

Stefano Pedone
fonte

-2

 vMYQUERY := 'SELECT COUNT(*) FROM ALL_OBJECTS WHERE OWNER = UPPER(''MFI_IDBI2LIVE'') AND OBJECT_TYPE = ''TABLE'' 
    AND OBJECT_NAME  =''' || vTBL_CLIENT_MASTER || '''';
    PRINT_STRING(VMYQUERY);
    EXECUTE IMMEDIATE  vMYQUERY INTO VCOUNTTEMP ;

PaOne
fonte

Isso não se aplica ao servidor sql.

Robert Lujo

Obtendo resultado de SQL dinâmico em uma variável para sql-server

Respostas: