Aliasing de um comando no vim

Vim é o meu editor de texto preferido quando programa e, portanto, sempre encontro um problema particularmente irritante.

Freqüentemente, quando preciso salvar o buffer rapidamente e continuar com outras tarefas diversas, faço as tarefas típicas

:w

No entanto, eu - o que parece ser mais de 50% do tempo - sempre consigo capitalizar isso :w. Naturalmente, o vim grita comigo porque Wé um comando inválido

E492: Not an editor command: W

Minha pergunta é como alguém pode usar o comando colon-command no vim . Particularmente, você poderia exemplificar como criar um alias Wpara w.

Estou ciente do processo para mapear chaves para determinados comandos . Infelizmente, não é isso que estou procurando.

Para deixar a conclusão intocada, tente usar

cnoreabbrev W w

, ele será substituído Wna linha de comando por w, mas somente se não for seguido nem precedido pelo caractere da palavra, :W<CR>será substituído por :w<CR>, mas :Writenão será. (Observe que isso afeta quaisquer comandos que correspondam, incluindo aqueles que você não pode esperar, por exemplo, o comando :saveas W Zserá substituído por :saveas w Z, portanto, tenha cuidado com isso.)

Atualizar

Aqui está como eu escreveria agora :

cnoreabbrev <expr> W ((getcmdtype() is# ':' && getcmdline() is# 'W')?('w'):('W'))

Como uma função:

fun! SetupCommandAlias(from, to)
  exec 'cnoreabbrev <expr> '.a:from
        \ .' ((getcmdtype() is# ":" && getcmdline() is# "'.a:from.'")'
        \ .'? ("'.a:to.'") : ("'.a:from.'"))'
endfun
call SetupCommandAlias("W","w")

Isso verifica se o tipo de comando é :e o comando é W, portanto, é mais seguro do que apenas cnoreabbrev W w.

Com pesquisas complementares, descobri que alguém fez quase a mesma pergunta que eu.

:command <AliasName> <string of command to be aliased>

fará o truque.

Esteja ciente de que, como Richo aponta, o comando do usuário deve começar com uma letra maiúscula.

Acho que o mapeamento da ;chave :seria uma solução melhor e o tornaria mais produtivo para digitar outros comandos.

nnoremap ; :
vnoremap ; :

A melhor solução envolve escrever uma função personalizada para lidar com abreviações que ocorrem apenas no início da barra de comandos.

Para isso, adicione o seguinte arquivo vimrc ou qualquer outro lugar.

" cabs - less stupidity                                                      {{{
fu! Single_quote(str)
  return "'" . substitute(copy(a:str), "'", "''", 'g') . "'"
endfu
fu! Cabbrev(key, value)
  exe printf('cabbrev <expr> %s (getcmdtype() == ":" && getcmdpos() <= %d) ? %s : %s',
    \ a:key, 1+len(a:key), Single_quote(a:value), Single_quote(a:key))
endfu
"}}}

" use this custom function for cabbrevations. This makes sure that they only
" apply in the beginning of a command. Else we might end up with stuff like
"   :%s/\vfoo/\v/\vbar/
" if we happen to move backwards in the pattern.

" For example:
call Cabbrev('W', 'w')

Algumas abreviações úteis do material de origem onde encontrei este material:

call Cabbrev('/',   '/\v')
call Cabbrev('?',   '?\v')

call Cabbrev('s/',  's/\v')
call Cabbrev('%s/', '%s/\v')

call Cabbrev('s#',  's#\v')
call Cabbrev('%s#', '%s#\v')

call Cabbrev('s@',  's@\v')
call Cabbrev('%s@', '%s@\v')

call Cabbrev('s!',  's!\v')
call Cabbrev('%s!', '%s!\v')

call Cabbrev('s%',  's%\v')
call Cabbrev('%s%', '%s%\v')

call Cabbrev("'<,'>s/", "'<,'>s/\v")
call Cabbrev("'<,'>s#", "'<,'>s#\v")
call Cabbrev("'<,'>s@", "'<,'>s@\v")
call Cabbrev("'<,'>s!", "'<,'>s!\v")

Talvez você queira mapear uma de suas teclas de função (F1..F12) para: w? Em seguida, coloque isso no seu .vimrc:

noremap  <f1> :w<return>
inoremap <f1> <c-o>:w<return>

(ctrl-o no modo de inserção muda temporariamente para o modo normal).

Suponha que você queira adicionar um alias para o comando tabnew no gvim. você pode simplesmente digitar o seguinte comando no arquivo .vimrc (se não estiver na pasta inicial, crie um)

cabbrev t tabnew

O mais seguro e fácil é um plug-in como o cmdalias.vim ou meu vim-alias da atualização recente que leva em consideração

• espaços em branco ou modificadores anteriores, como :sil(ent)(!)ou :redi(r),
• modificadores de faixa, como '<,'>para a seleção visual atual,
• escapar caracteres especiais como aspas e
• verifique se o alias escolhido é uma abreviação de linha de comando válida.