Crie uma pasta com lote, mas apenas se ainda não existir

Alguém pode me dizer como fazer o seguinte em um script em lote do Windows? ( *.bat):

• Crie uma pasta apenas se ela ainda não existir

Em mais detalhes, desejo criar uma pasta chamada VTSna C:\unidade, mas apenas se essa pasta ainda não existir. Não quero substituir o conteúdo da pasta, se ela já existir, e o lote for executado.

Você apenas usa isto: if not exist "C:\VTS\" mkdir C:\VTSele criará um diretório apenas se a pasta não existir.

Observe que esse teste de existência retornará verdadeiro somente se o VTS existir e for um diretório. Se não estiver lá, ou como um arquivo, o comando mkdir será executado e deverá causar um erro. Convém verificar se o VTS também existe como um arquivo.

if exist C:\VTS\NUL echo "Folder already exists"

if not exist C:\VTS\NUL echo "Folder does not exist"

Consulte também https://support.microsoft.com/en-us/kb/65994

(Atualização em 7 de março de 2018; Artigo da Microsoft em baixo, arquivo em https://web.archive.org/web/20150609092521/https://support.microsoft.com/en-us/kb/65994 )

Basta ligar, mkdir C:\VTSnão importa o quê. Ele simplesmente informa que o subdiretório já existe.

Editar: como outros observaram, isso define o% ERRORLEVEL% se a pasta já existir. Se o seu lote (ou qualquer processo chamado) não se importar com o nível de erro, esse método funcionará bem. Como a pergunta não fez menção de evitar o nível de erro, esta resposta é perfeitamente válida. Ele atende às necessidades de criação da pasta, se ela não existir, e não substitui o conteúdo de uma pasta existente. Caso contrário, siga a resposta de Martin Schapendonk .

mkdir C:\VTS 2> NUL

crie uma pasta chamada VTSe faça a saída A subdirectory or file TEST already existspara NUL.

ou

(C:&(mkdir "C:\VTS" 2> NUL))&

alterar a letra de unidade para C:, mkdir, erro de saída para NULe executar o próximo comando.

set myDIR=LOG
IF not exist %myDIR% (mkdir %myDIR%)

Eu uso dessa maneira, você deve colocar uma barra invertida no final do nome do diretório para evitar que exista um local em um arquivo sem extensão com o mesmo nome que o diretório especificado, nunca use "C: \ VTS" porque pode ser um arquivo existe com o nome "VTS" salvo na partição "C:" , a maneira correta é usar "C: \ VTS \" , verifique a barra invertida após o VTS , assim é o caminho certo.

@echo off
@break off
@title Create folder with batch but only if it doesn't already exist - D3F4ULT
@color 0a
@cls

setlocal EnableDelayedExpansion

if not exist "C:\VTS\" (
  mkdir "C:\VTS\"
  if "!errorlevel!" EQU "0" (
    echo Folder created successfully
  ) else (
    echo Error while creating folder
  )
) else (
  echo Folder already exists
)

pause
exit

Você pode usar:

if not exist "C:\VTS\" mkdir "C:\VTS"

Você também pode expandir o código para substituir os arquivos esperados ausentes.

if not exist "C:\VTS\important.file" echo. > "C:\VTS\important.file"

Eu criei isso para o meu script que eu uso no meu trabalho para eyebeam.

:CREATES A CHECK VARIABLE

set lookup=0

:CHECKS IF THE FOLDER ALREADY EXIST"

IF EXIST "%UserProfile%\AppData\Local\CounterPath\RegNow Enhanced\default_user\" (set lookup=1)

:IF CHECK is still 0 which means does not exist. It creates the folder

IF %lookup%==0 START "" mkdir "%UserProfile%\AppData\Local\CounterPath\RegNow Enhanced\default_user\"