Vim: Criando diretórios pai ao salvar

Se eu chamar, vim foo/bar/somefilemas foo/barainda não existir, o Vim se recusará a salvar.

Eu sei que poderia mudar para um shell ou fazer a :!mkdir foo/barpartir do Vim, mas sou preguiçoso :) Existe uma maneira de fazer o Vim fazer isso automaticamente quando ele salva o buffer?

augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * if expand("<afile>")!~#'^\w\+:/' && !isdirectory(expand("%:h")) | execute "silent! !mkdir -p ".shellescape(expand('%:h'), 1) | redraw! | endif
augroup END

Observe as condições: expand("<afile>")!~#'^\w\+:/'impedirá o vim de criar diretórios para arquivos como ftp://*e !isdirectoryevitará chamadas caras do mkdir.

Atualização : solução ligeiramente melhor que também verifica buftype não vazio e usa mkdir():

function s:MkNonExDir(file, buf)
    if empty(getbufvar(a:buf, '&buftype')) && a:file!~#'\v^\w+\:\/'
        let dir=fnamemodify(a:file, ':h')
        if !isdirectory(dir)
            call mkdir(dir, 'p')
        endif
    endif
endfunction
augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * :call s:MkNonExDir(expand('<afile>'), +expand('<abuf>'))
augroup END

Com base nas sugestões para minha pergunta, eis o que acabei fazendo:

function WriteCreatingDirs()
    execute ':silent !mkdir -p %:h'
    write
endfunction
command W call WriteCreatingDirs()

Isso define o :Wcomando. Idealmente, eu gostaria de ter todos :w!, :wq, :wq!, :walletc funcionam da mesma forma, mas não tenho certeza se é possível sem basicamente reimplementar todos eles com funções personalizadas.

Adicionei isso ao meu ~ / .vimrc

cnoremap mk. !mkdir -p <c-r>=expand("%:h")<cr>/

Se eu precisar criar o diretório em que estou, digite :mk.e o substitua por "! Mkdir -p / caminho / para / meu / arquivo /" e me permita revisar o comando antes de invocá-lo.

I fez :saveas!criar o diretório se ausente: https://github.com/henrik/dotfiles/commit/54cc9474b345332cf54cf25b51ddb8a9bd00a0bb

Este código solicitará que você crie o diretório :wou faça-o apenas com :w!:

augroup vimrc-auto-mkdir
  autocmd!
  autocmd BufWritePre * call s:auto_mkdir(expand('<afile>:p:h'), v:cmdbang)
  function! s:auto_mkdir(dir, force)
    if !isdirectory(a:dir)
          \   && (a:force
          \       || input("'" . a:dir . "' does not exist. Create? [y/N]") =~? '^y\%[es]$')
      call mkdir(iconv(a:dir, &encoding, &termencoding), 'p')
    endif
  endfunction
augroup END

Acho que consegui fazer isso em três linhas, combinando o que os outros estão dizendo nesta resposta.

Isso parece fazer o truque:

if has("autocmd")
  autocmd BufWritePre * :silent !mkdir -p %:p:h
end

Ele tenta criar a pasta automaticamente ao salvar um buffer. Se algo de ruim acontecer (por exemplo, problemas de permissão), ele simplesmente se cala e deixa a gravação do arquivo falhar.

Se alguém vir alguma falha óbvia, por favor poste um comentário. Eu não sou muito versado em vimscript.

EDIT: Notas graças ao ZyX

• Isso não funcionará se suas pastas tiverem espaços (aparentemente elas não foram escapadas adequadamente ou algo assim)
• Ou se você estiver fazendo pseudo arquivos.
• Ou se você estiver adquirindo seu vimrc.
• Mas filho, é curto.