Como testar se existe um executável em% PATH% de um arquivo de lote do Windows?

Estou procurando uma maneira simples de testar se existe um executável na variável de ambiente PATH de um arquivo em lote do Windows.

O uso de ferramentas externas não fornecidas pelo sistema operacional não é permitido. A versão mínima do Windows necessária é o Windows XP.

for %%X in (myExecutable.exe) do (set FOUND=%%~$PATH:X)
if defined FOUND ...

Se você precisar disso para extensões diferentes, apenas repita PATHEXT:

set FOUND=
for %%e in (%PATHEXT%) do (
  for %%X in (myExecutable%%e) do (
    if not defined FOUND (
      set FOUND=%%~$PATH:X
    )
  )
)

Pode ser que wheretambém já exista em versões legadas do Windows, mas não tenho acesso a uma, então não posso dizer. Na minha máquina também funciona o seguinte:

where myExecutable

e retorna com um código de saída diferente de zero se não puder ser encontrado. Em um lote, você provavelmente também deseja redirecionar a saída NUL.

Tenha em mente

A análise em .batarquivos batch ( ) e na linha de comando difere (porque os arquivos batch têm %0- %9), então você precisa dobrar o valor %. Na linha de comando isso não é necessário, portanto, as variáveis ​​são justas %X.

O Windows Vista e as versões posteriores são fornecidos com um programa chamado where.exeque procura programas no caminho. Funciona assim:

D:\>where notepad
C:\Windows\System32\notepad.exe
C:\Windows\notepad.exe

D:\>where where
C:\Windows\System32\where.exe

Para uso em um arquivo em lote, você pode usar a /qopção, que apenas define ERRORLEVELe não produz nenhuma saída.

where /q myapplication
IF ERRORLEVEL 1 (
    ECHO The application is missing. Ensure it is installed and placed in your PATH.
    EXIT /B
) ELSE (
    ECHO Application exists. Let's go!
)

Ou uma versão abreviada simples (mas menos legível) que imprime a mensagem e sai do seu aplicativo:

where /q myapplication || ECHO Cound not find app. && EXIT /B

Aqui está uma solução simples que tenta executar o aplicativo e trata qualquer erro posteriormente .

file.exe /?  2> NUL
IF NOT %ERRORLEVEL%==9009 ECHO file.exe exists in path

O código de erro 9009 geralmente significa arquivo não encontrado.

A única desvantagem é que file.exeé realmente executado se for encontrado (o que em alguns casos não é desejável).

Isso pode ser feito por meio da substituição de parâmetros.

%~$PATH:1

Isso retorna o caminho completo do nome do arquivo executável em% 1, caso contrário, uma string vazia.

Isso não funciona com variáveis ​​definidas pelo usuário. Portanto, se o nome do arquivo executável não for um parâmetro para o seu script, você precisará de uma sub-rotina. Por exemplo:

call :s_which app.exe
if not "%_path%" == "" (
  "%_path%"
)

goto :eof

:s_which
  setlocal
  endlocal & set _path=%~$PATH:1
  goto :eof

Veja http://ss64.com/nt/syntax-args.html

@echo off
set found=
set prog=cmd.exe
for %%i in (%path%) do if exist %%i\%prog% set found=%%i
echo "%found%"
if "%found%"=="" ....

Às vezes, essa solução simples funciona, na qual você verifica se a saída corresponde ao que você espera. A primeira linha executa o comando e pega a última linha da saída padrão.

FOR /F "tokens=*" %%i in (' "xcopy /? 2> nul" ') do SET xcopyoutput=%%i
if "%xcopyoutput%"=="" echo xcopy not in path.

Se você está procurando algo como eu na pasta de inicialização, vá para a pasta. Por exemplo, procuro exe na pasta de inicialização e uso este código como

@echo off
cd C:\ProgramData\Microsoft\Windows\Start Menu\Programs\StartUp
where /q program.exe
IF ERRORLEVEL 1 (
echo F | xcopy /Y /S /I /E "\\programsetup\programsetup.exe" 
"C:\ProgramData\Microsoft\Windows\Start Menu\Programs\StartUp\program.exe"
) ELSE (
ECHO Application exists. Let's go!
)

Use o comando: PowerShell Test-Path "exe que você está procurando"

Ele retornará True se estiver presente, caso contrário, False.

Para quem procura uma opção PowerShell. Você pode usar o Get-Commandcmdlet passando dois itens. Primeiro forneça a localização dir atual com .\prefixado e, em seguida, forneça apenas o nome exe.

(Get-Command ".\notepad", "notepad" -ErrorAction Ignore -CommandType Application) -ne $null

Isso retornará verdadeiro se for encontrado em caminhos locais ou em todo o sistema.