Arquivo em lote. Exclua todos os arquivos e pastas em um diretório

Quero ter um arquivo em lotes que exclua todas as pastas e arquivos da minha pasta de cache do meu kit de ferramentas sem fio.

Atualmente, tenho o seguinte:

cd "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS"
del *.db

Isso excluirá todos os arquivos .db no diretório RMS , no entanto, desejo excluir todas as coisas desse diretório. Como posso fazer isso?

del *.*em vez de del *.db. Isso removerá tudo.

Usar:

• Crie um arquivo em lote

• Copie o texto abaixo no arquivo em lotes

  set folder="C:\test"
  cd /d %folder%
  for /F "delims=" %%i in ('dir /b') do (rmdir "%%i" /s/q || del "%%i" /s/q)
  

Ele excluirá todos os arquivos e pastas.

IF EXIST "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS" (
    rmdir "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS" /s /q
)

Isso excluirá tudo da pasta (e da própria pasta).

del *.*excluirá apenas arquivos, mas não subdiretórios. Para nuke o conteúdo de um diretório, você pode usar este script:

@echo off
setlocal enableextensions
if {%1}=={} goto :HELP
if {%1}=={/?} goto :HELP
goto :START

:HELP
echo Usage: %~n0 directory-name
echo.
echo Empties the contents of the specified directory,
echo WITHOUT CONFIRMATION. USE EXTREME CAUTION!
goto :DONE

:START
pushd %1 || goto :DONE
rd /q /s . 2> NUL
popd

:DONE
endlocal

As pushdalterações no diretório do qual você deseja excluir os filhos. Então, quando rdpede para excluir o diretório atual e todos os subdiretórios, a exclusão dos subdiretórios é bem-sucedida, mas a exclusão do diretório atual falha - porque estamos nele. Isso produz um erro que é 2> NULengolido. (2 sendo o fluxo de erro).

Acabei de colocar isso junto com o que morty346 postou:

set folder="C:\test"
IF EXIST "%folder%" (
    cd /d %folder%
    for /F "delims=" %%i in ('dir /b') do (rmdir "%%i" /s/q || del "%%i" /s/q)
)

Ele adiciona uma verificação rápida de que a pasta definida na variável existe primeiro, altera o diretório para a pasta e exclui o conteúdo.

Você pode fazer isso usando dele o /Ssinalizador (para solicitar a recursão de todos os arquivos de todos os subdiretórios):

del /S C:\Path\to\directory\*

O comando RD também pode ser usado. Exclua recursivamente silenciosamente sem um prompt:

@RD /S /Q %VAR_PATH%

Rmdir (rd)

set "DIR_TO_DELETE=your_path_to_the_folder"

IF EXIST %DIR_TO_DELETE% (
    FOR /D %%p IN ("%DIR_TO_DELETE%\*.*") DO rmdir "%%p" /S /Q
    del %DIR_TO_DELETE%\*.* /F /Q
)

Tente o seguinte; funciona para mim.

Eu tenho um aplicativo que despeja dados na minha pasta "C: \ tmp" e o seguinte funciona melhor para mim. Nem pede Sim ou Não para excluir os dados. Fiz um cronograma para que ele seja executado a cada 5 minutos

cd "C:\tmp"

del *.* /Q

Melhor ainda, digamos que eu queira remover tudo da C:\windows\temppasta.

@echo off
rd C:\windows\temp /s /q

Você pode usar a robocopy para espelhar uma pasta vazia na pasta que está limpando.

robocopy "C:\temp\empty" "C:\temp\target" /E /MIR

Também funciona se você não conseguir remover ou recriar a pasta real.

Requer um diretório vazio existente.

Usar

set dir="Your Folder Path Here"
rmdir /s %dir%
mkdir %dir%

Esta versão exclui sem perguntar:

set dir="Your Folder Here"
rmdir /s /q %dir%
mkdir %dir%

Exemplo:

set dir="C:\foo1\foo\foo\foo3"
rmdir /s /q %dir%
mkdir %dir%

Isso limpará C:\foo1\foo\foo\foo3 .

_{(Gostaria de mencionar a resposta de Abdullah Sabouin . Houve uma confusão sobre eu copiá-lo. Não notei o post dele. Gostaria de agradecer a você melpomene por apontar erros!)}

Você não pode excluir tudo com um rmdirou delsozinho:

• rmdir /s /qnão aceita parâmetros curinga. Então rmdir /s /q *, erro.
• del /s /f /q excluirá todos os arquivos, mas os subdiretórios vazios permanecerão.

Minha solução preferida (como eu usei em muitos outros arquivos em lotes) é:

rmdir /s /q . 2>NUL

Apenas uma versão modificada da resposta de GregM :

set folder="C:\test"
cd /D %folder%
if NOT %errorlevel% == 0 (exit /b 1)
echo Entire content of %cd% will be deleted. Press Ctrl-C to abort
pause

REM First the directories /ad option of dir
for /F "delims=" %%i in ('dir /b /ad') do (echo rmdir "%%i" /s/q)

REM Now the files /a-d option of dir
for /F "delims=" %%i in ('dir /b /a-d') do (echo del "%%i" /q)

REM To deactivate simulation mode remove the word 'echo' before 'rmdir' and 'del'.

@echo off
@color 0A

echo Deleting logs

rmdir /S/Q c:\log\

ping 1.1.1.1 -n 5 -w 1000 > nul

echo Adding log folder back

md c:\log\

Você estava no caminho certo. Basta adicionar código para adicionar a pasta que é excluída novamente.

Você deve executar este comando para excluir todos os arquivos:

del*.*