Como encontrar a primeira célula vazia no excel

Estou tentando obter o valor em vermelho abaixo, que corresponde à primeira célula não vazia na linha e ter a data correspondente a cada:

Eu tentei essa fórmula, mas ela não funcionou por algum motivo:

=INDEX('Charge 2018 par ressource'!E16:P16;1;MATCH(1;(1-ISBLANK('Charge 2018 par ressource'!E16:P16));0))

Alguma idéia de qual fórmula matricial usar para esse assunto?

microsoft-excel worksheet-function MopMop
fonte

Como exatamente isso não funciona? Você já tentou avaliar ? Você o inseriu como uma fórmula de matriz ?

Máximo Juhász

Sim, tentei avaliar a fórmula, mas isso não me ajuda a encontrar a solução. Além disso, se funcionasse, apenas me traria de volta o valor da primeira célula não vazia, mas não a data em que está a primeira célula não vazia. Qual é o que eu estou procurando #

MopMop

Respostas:

Você está procurando a primeira célula (1-ISBLANK('Charge 2018 par ressource'!E16:P16)) não vazia com Nenhuma delas está em branco.

ISBLANKprocura células verdadeiramente em branco, nada nelas, nenhuma fórmula, não 0. Você está procurando a primeira não 0célula.

Então use:

(1-('Charge 2018 par ressource'!E16:P16=0))

Além disso, se você quiser a data em que precisa da primeira referência para referenciar a linha da data e não o campo inteiro, presumo que a linha seja a linha 1 aqui, se diferentes forem alteradas para a linha com as datas:

'Charge 2018 par ressource'!E$1:P$1

Portanto, sua fórmula de matriz seria:

=INDEX('Charge 2018 par ressource'!E$1:P$1;MATCH(1;(1-('Charge 2018 par ressource'!E16:P16=0));0))

Sendo uma fórmula de matriz, deve ser confirmada com Ctrl-Shift-Enter em vez de Enter ao sair do modo de edição.

Você também pode usar esta fórmula que é inserida normalmente:

=INDEX('Charge 2018 par ressource'!$1:$1;AGGREGATE(15;6;COLUMN('Charge 2018 par ressource'!E16:P16)/('Charge 2018 par ressource'!E16:P16<>0);1))

Scott Craner
fonte