Como somar um intervalo de células com valores N / A?

11

Eu tenho um intervalo e preciso somar usando a função SUM, mas o resultado é N / A se houver algum valor N / A. Como posso fazer a função SUM tratar o valor N / A como valor 0? Por favor ajude!

microsoft-excel-2010 Nam G VU
fonte

Respostas:

15

Usar fórmula de matriz

=SUM(IF(ISNA(A1:A4),0,A1:A4))

Pressione Ctrl+ Shift+ Enterapós inserir a fórmula

Nota: Substitua A1:A4por seu intervalo

Wilson
fonte
1
+1: uma boa melhoria na minha solução - não é necessário modificar os dados originais.
Mike Fitzpatrick
1
Agradável. Nunca pensei em usar uma fórmula de matriz. Fiquei feliz em usar = SUMIF (A1: A4, "<> # N / A") até descobrir que ele quebra se a planilha for aberta em uma cópia do Excel localizada em outro idioma! Infelizmente, substituir "<> # N / A" por "ISNA ()" não funciona, mas a fórmula da matriz é uma boa solução multilíngue. Infelizmente, não é uma abordagem adequada para o mesmo desafio com AVERAGEIF () ... :-(
Joe Carroll
@JoeCarroll, você pode usar=AVERAGE(IF(ISNA(A1:A4),"",A1:A4))
wilson
Obrigado @wilson! Quando eu pensei brevemente, não pensei em usar "" em vez de zero, parvo :-) Usar zero afeta o tamanho da amostra, é claro, o que me levou a descartar a solução, mas as células vazias são simplesmente ignoradas.
Joe Carroll
Não funciona com o mágico Cr @ pXcel 2013, mas a resposta abaixo (= agregada) funciona como charme!
5

A maneira mais fácil:

Use SUMIFo valor> 0.

Portanto, a sintaxe para esse é

=SUMIF(A1:B2, "> 0")

Você obterá o mesmo resultado, pois ele ignorará quaisquer valores não numéricos ou 0.

JNK
fonte
2
Sua sugestão não funcionará com números negativos. Obrigado mesmo assim.
Nam G VU
1
Poderia fazer =SUMIF(A1:B2, ">=0") + SUMIF(A1:B2, "<0")para incluir números negativos. Eu suspeito que seria mais rápido que a solução de fórmula de matriz aceita, se o desempenho for uma preocupação.
kizzx2
3

Há uma nova função no Excel que adicionará todos os valores positivos ou negativos, ignorando os NAs. 

=aggregate(9,6, range of your data)

9 é usado como soma e 6 é para ignorar todos os NAs. Existem outras opções também, além da adição. Por exemplo, você pode fazer produto, desvio padrão e assim por diante.

Mais informações sobre AGGREGATE aqui .

Muhammad Wajid Raza
fonte
solução elegante para o Excel 2010 e em diante :)
wilson
0

Use SUBTOTAL em vez disso:

=SUBTOTAL(9,A1:A50)
variante
fonte
Estou tentando sumtotal, mas eu tenho o mesmo problema que comsum
fguillen
0

Você pode converter # N / A em zeros no seu intervalo de fontes e, em seguida, usar a função SUM normal:

= SE (ISNA (fórmula original), 0, fórmula original)
Mike Fitzpatrick
fonte
1
Desde o escritório 2007, há um novo recurso,, IFERRORe pode ser assim: =IFERROR(OriginalFormula,0)tornando-o muito melhor.
Michael
@ agentmike, concordou, eu o uso com frequência atualmente.
Mike Fitzpatrick
0

Se houver fórmulas que eu copiei como números, substitua # N / A na coluna por 0 e, em seguida, some como normalmente

Cynthia
fonte
-1

Desta forma, parece funcionar: 

SUMIF(range;"<>#N/A";range)

Não é tão robusto, mas eficaz!

Bruno
fonte