Estou procurando uma ferramenta para permitir a pesquisa incremental reversa com suporte a expressões regulares simples (ou apenas várias correspondências). Por exemplo, se eu quiser encontrar o comando 'foo bar baz', poderia fazer algo como o seguinte para encontrar o comando rapidamente:

O CRTL-R (inicia a pesquisa) digite 'foo' (corresponde ao comando mais recente usando foo) continue digitando 'foo | baz' (corresponde ao comando mais recente que contém 'foo' AND 'baz'.

Será que algo assim existe? Se não, como eu poderia implementá-lo eu mesmo?

Widget personalizado history-incremental-multi-searchparazsh

Configuração

Crie um diretório e inclua-o no seu. $fpathPor exemplo, eu criei um diretório ~/.zsh/functionse a linha fpath=($HOME/.zsh/functions $fpath)no meu .zshrc.

Coloque o seguinte em um arquivo nomeado history-incremental-multi-searchnesse diretório.

emulate -L zsh
setopt extended_glob

local oldbuffer=$BUFFER
local -i oldcursor=$CURSOR

local dir                # search direction
local chars              # input buffer
local -a words           # search terms
local -a found           # all history items that match first term
local -i hindex=$HISTNO  # current 
local -i lmatch          # last matched history item (for prev/next)

if [[ $WIDGET == *forward* ]]; then
    dir=fwd
else
    dir=bck
fi

function find-next {
    # split the input buffer on spaces to get search terms
    words=(${(s: :)chars})

    # if we have at least one search term
    if (( $#words )); then
        # get all keys of history items that match the first
        found=(${(k)history[(R)*$words[1]*]})
        if (( $#found )); then
            # search in widget direction by default
            # but accept exception in $1 for "prev match"
            search-${1:-$dir}
        else
            # no matches
            lmatch=$HISTNO
        fi
    else
        # no search terms
        lmatch=$HISTNO
        BUFFER=$oldbuffer
        CURSOR=$oldcursor
    fi
}

function search-fwd {
    # search forward through matches
    local -i i
    for (( i = $#found; i > 0; i-- )); do
        # but not before hindex as we're searching forward
        if [[ $found[$i] -gt $hindex ]]; then
            set-match $found[$i]
        fi
    done
}

function search-bck {
    # search backward through matches
    local -i i
    for (( i = 1; i <= $#found; i++ )); do
        # but not beyond hindex as we're searching backward
        if [[ $found[$i] -lt $hindex ]]; then
            set-match $found[$i]
        fi
    done
}

function set-match {
    # match history item against all terms and select it if successful
    local match=1
    local -i i
    for (( i = 2; i <= $#words; i++ )); do
        if [[ $history[$1] != *$words[$i]* ]]; then
            match=0
            break
        fi
    done
    if [[ $match -ne 0 ]]; then
        lmatch=$1
        BUFFER=$history[$1]
        CURSOR=$#BUFFER
        break
    fi
}

# display sub prompt
zle -R "${dir}-i-search-multi:"

# handle input keys
while read -k; do
    case $REPLY in
        # next
        $'\C-n' )
            hindex=$lmatch
            find-next
            ;;
        # prev
        $'\C-p' )
            hindex=$lmatch
            if [[ $dir == fwd ]]; then
                find-next bck
            else
                find-next fwd
            fi
            ;;
        # break
        $'\e' | $'\C-g' )
            BUFFER=$oldbuffer
            CURSOR=$oldcursor
            break
            ;;
        # accept
        $'\C-m' | $'\C-j' )
            if [[ $lmatch -eq $HISTNO ]]; then
                BUFFER=$oldbuffer
                CURSOR=$oldcursor
            else
                HISTNO=$lmatch
            fi
            break
            ;;
        # erase char
        $'\C-h' | $'\C-?' )
            chars=$chars[1,-2]
            hindex=$HISTNO
            find-next
            ;;
        # erase word
        $'\C-w' )
            if [[ $chars =~ \  ]]; then
                chars=${chars% *}
            else
                chars=
            fi
            hindex=$HISTNO
            find-next
            ;;
        # kill line
        $'\C-u' )
            chars=
            hindex=$HISTNO
            find-next
            ;;
        # add unhandled chars to buffer
        * )
            chars=${chars}${REPLY}
            hindex=$HISTNO
            find-next
            ;;
    esac

    zle -R "${dir}-i-search-multi: $words"
done

Coloque isso ou obtenha-o do seu .zshrc:

autoload -U history-incremental-multi-search

# make new widgets from function
zle -N history-incremental-multi-search-backward history-incremental-multi-search
zle -N history-incremental-multi-search-forward history-incremental-multi-search

# bind the widgets to keys
bindkey '^Xr' history-incremental-multi-search-backward
bindkey '^Xs' history-incremental-multi-search-forward

Usar

Agora você deve ser capaz de iniciar uma pesquisa incremental para trás com Ctrl+X, r, para a frente com Ctrl+X, s.

Digite seus termos de pesquisa separados por espaço. As seguintes teclas estão disponíveis para controlá-lo:

• ← Backspace: apagar caractere

• Ctrl+W: apagar palavra

• Ctrl+U: matar linha

• Ctrl+N: próxima partida

• Ctrl+P: partida anterior

• Ctrl+G/ Esc: cancelar pesquisa

• Enter: aceitar

Esta solução provavelmente pode ser bastante simplificada. É mais uma prova de conceito funcional, com muito espaço para melhorias.

Você pode verificar sua história:

history | egrep '(foo|baz)'

Espero que ajude.

Com base na resposta de @ peth:

O Zsh agora vem com history-incremental-pattern-search-backward, você não precisa defini-lo. Basta adicionar ligação de chave. Prefiro substituir ^Radicionando a seguinte linha a .zshrc:

bindkey '^R' history-incremental-pattern-search-backward

Agora você pode usar operadores glob (sic! Not rexex) em sua pesquisa.