Algum ajuste do Spotify com atalho de teclado para faixas em 'estrela'?

Sou assinante premium do Spotify e um geek obsessivo da produtividade.

Uma coisa que realmente me incomoda é que não há um atalho de teclado para marcar uma faixa com uma estrela (ou seja, adicione uma faixa aos favoritos). Eu gosto de deixar o rádio Spotify ligado enquanto estou trabalhando e, de vez em quando, tenho que clicar e clicar com o botão direito na faixa e selecionar 'Star' sempre que ouvir uma música que realmente gosto.

Existe algum ajuste / plug-in do Spotify por aí que me permita 'estrelar' as faixas com um atalho de teclado?

Claro, use o AutoHotkey !

Depois de instalá-lo, coloque isso no seu arquivo AutoHotkey.ahk:

#*::
WinWait, Spotify, 
IfWinNotActive, Spotify, , WinActivate, Spotify, 
WinWaitActive, Spotify, 
MouseClick, left,  79,  90
Sleep, 100
MouseClick, left,  256,  152
Sleep, 100
return

Isso adiciona uma tecla de atalho Win + Asterisk que exibirá a faixa que está tocando.

Você também pode estar interessado em outros atalhos do Spotify para AutoHotkey.

Eu tentei o outro atalho da Autohotkey e não funcionou para mim (apenas mudei para spotify e cliquei em dois pontos mortos). Eu criei o seguinte, que funciona desde que você tenha selecionado "Grande trabalho artístico em execução":

CoordMode, Mouse, Relative
;star currently playing
+^l::
SpotifyWinHeight = 1050 ;set to 1080 - 30 for small taskbar size, just in case WinGetPos doesn't work for some reason
WinGetActiveTitle, CurWindow
WinActivate Spotify
WinWaitActive Spotify
WinGetPos,  ,  ,  , SpotifyWinHeight, Spotify
;          X  Y  W  H, we don't care about anything but height
RightClickTarget := SpotifyWinHeight - 250
ContextMenuTarget := RightClickTarget + 110
MouseMove, 100, %RightClickTarget%
Click Right
Sleep, 50
MouseMove, 180, %ContextMenuTarget%
Sleep, 50
Click
WinActivate %CurWindow%
return

Faz o seguinte:

• Armazena a janela atualmente ativa
• Ativa o Spotify
• Calcula os deslocamentos para clicar na capa do álbum em relação à janela do spotify
• Estrelas que estão sendo reproduzidas no momento (por meio de arte com o botão direito do mouse, clique com o botão esquerdo em Estrela)
• Restaura qualquer janela que estivesse ativa antes de tudo isso

Não é perfeito (provavelmente não ficará feliz se, por algum motivo, você tiver o spotify pendurado principalmente na tela para a direita), mas faz o trabalho na maioria dos casos.

Com estrela não é mais uma coisa.

Acesse aqui as perguntas e respostas atualizadas.

Antiga resposta abaixo aqui ...

Aqui está outra solução AutoHotkey . Existem comentários liberais. Além disso, a documentação e os fóruns do AutoHotkey são ótimos lugares para aprender, se desejado.

Pressionar Control + Shift + * marcará a música ativa com uma estrela.
Uma das principais características desse script é que ele verifica se a música já está estrelada e a deixa em paz se estiver.

^+*::
spotify = ahk_class SpotifyMainWindow
IfWinExist, %spotify%
{
;Store active window and mouse position.
WinGetActiveTitle, activeWindow
MouseGetPos x, y, winID

;Activate Spotify.
WinActivate %spotify%
WinWaitActive %spotify%

;Right click near the song title in the "Now Playing" box.
WinGetPos,  ,  ,  , spotifyHeight, %spotify%
MouseClick, Right, 100, spotifyHeight - 70, 1, 0

;Get the contents of the context menu.
WinWait, ahk_class #32768
SendMessage, 0x1E1      ; MN_GETHMENU
allContextMenuInfo := ErrorLevel

;The "Star" command is the 5th menu item.
;If the song is Unstarred the text is Star, and vice versa. But sometimes some wierd characters are included.
;The only reliable way I found is to check if the first letter is S.
menuText_StarUnstar := GetContextMenuItemText(allContextMenuInfo, 5)
StringGetPos, positionOfS, menuText_StarUnstar, S

;If S is the first letter, star the song.
notStarred := (%positionOfS% = 0)
If notStarred {
    ;Arrow down to the Star menu item and press enter.
    Send {Down}{Down}{Down}{Down}{Down}{Enter}
} Else {
    ;Just close the context menu.
    Send {Escape}
}

;Restore original window and mouse position.
WinActivate ahk_id %winID%
MouseMove %x%, %y%
}

Return

;Conext menu helper function.
GetContextMenuItemText(hMenu, nPos)
{
length := DllCall("GetMenuString"
        , "UInt", hMenu
        , "UInt", nPos
        , "UInt", 0 ; NULL
        , "Int", 0  ; Get length
        , "UInt", 0x0400)   ; MF_BYPOSITION
    VarSetCapacity(lpString, length + 1)
    length := DllCall("GetMenuString"
        , "UInt", hMenu
        , "UInt", nPos
        , "Str", lpString
        , "Int", length + 1
        , "UInt", 0x0400)
return lpString
}

Não tenho o representante para colocar isso em um comentário à resposta do GollyJer, mas notei ao tentar usar esse script que havia um problema com as teclas pressionadas {down} que, de alguma forma, faz com que a música destacada na lista de reprodução seja movida para baixo , em vez de descer no menu. Modifiquei-o para fazer um clique do mouse na entrada do menu "Estrela", em vez de usar as teclas, parece funcionar muito bem. Também o editei para minimizar o Spotify antes de voltar para a janela que você estava usando, se fosse minimizado para começar.

^+*::
spotify = ahk_class SpotifyMainWindow
IfWinExist, %spotify%
{
WinGet, MMX, MinMax, %spotify%
;Store active window and mouse position.
WinGetActiveTitle, activeWindow
MouseGetPos x, y, winID

;Activate Spotify.
WinActivate %spotify%
WinWaitActive %spotify%

;Right click near the song title in the "Now Playing" box.
WinGetPos,  ,  ,  , spotifyHeight, %spotify%
MouseClick, Right, 100, spotifyHeight - 70, 1, 0

;Get the contents of the context menu.
WinWait, ahk_class #32768
SendMessage, 0x1E1      ; MN_GETHMENU
allContextMenuInfo := ErrorLevel

;The "Star" command is the 5th menu item.
;If the song is Unstarred the text is Star, and vice versa. But sometimes some wierd characters are included.
;The only reliable way I found is to check if the first letter is S.
menuText_StarUnstar := GetContextMenuItemText(allContextMenuInfo, 5)
StringGetPos, positionOfS, menuText_StarUnstar, S

;If S is the first letter, star the song.
notStarred := (%positionOfS% = 0)
If notStarred {
    ;Arrow down to the Star menu item and press enter.
    MouseClick, Left, 20, -120, 1, 0,, R
} Else {
    ;Just close the context menu.
    Send {Escape}
}

;Restore original window and mouse position.
IfEqual MMX, -1, WinMinimize, %spotify%
WinActivate ahk_id %winID%
MouseMove %x%, %y%
}

Return

;Context menu helper function.
GetContextMenuItemText(hMenu, nPos)
{
length := DllCall("GetMenuString"
        , "UInt", hMenu
        , "UInt", nPos
        , "UInt", 0 ; NULL
        , "Int", 0  ; Get length
        , "UInt", 0x0400)   ; MF_BYPOSITION
    VarSetCapacity(lpString, length + 1)
    length := DllCall("GetMenuString"
        , "UInt", hMenu
        , "UInt", nPos
        , "Str", lpString
        , "Int", length + 1
        , "UInt", 0x0400)
return lpString
}

Você também pode experimentar o meu aplicativo Spotify, Twinkle , que é uma solução independente de plataforma e layout de GUI para assistir músicas do Spotify com um único clique.

As soluções que dependem da existência de um comando "Star" não funcionam mais ... não há mais um comando Star, mas "Starred" é uma pasta na qual os itens podem ser adicionados. Este script faz isso.

; Spotify "Star Song"
^+*::
spotify = ahk_class SpotifyMainWindow
IfWinExist, %spotify%
{
;Store active window and mouse position.
WinGetActiveTitle, activeWindow
MouseGetPos x, y, winID

;Activate Spotify.
WinActivate %spotify%
WinWaitActive %spotify%

;Right click near the song title in the "Now Playing" box.
WinGetPos,  ,  ,  , spotifyHeight, %spotify%
MouseClick, Right, 100, spotifyHeight - 70, 1, 0

;Open Add To... sub-menu
Send {A}

;The "Starred" command is the 2nd menu item. If the song is Starred it will be disabled.
Send {Down}{Enter}

;Restore original window and mouse position.
WinActivate ahk_id %winID%
MouseMove %x%, %y%
}

Return

O Spotify não tem mais a "estrela", e também não consigo recuperar o conteúdo do menu de contexto, então esse método olha para uma cor de pixel no menu de contexto e usa as teclas de seta para selecionar. Funciona se maximizado, minimizado e se a arte do álbum for grande ou pequena.

^+*::
{
    spotify = ahk_class SpotifyMainWindow
    IfWinExist, %spotify% 
    {
        ;Store active window and mouse position.
        WinGet, MMX, MinMax, %spotify%
        WinGetActiveTitle, activeWindow
        MouseGetPos x, y, winID

        ;Activate Spotify.
        WinActivate %spotify%
        WinWaitActive %spotify%

        ;Get maximised status
        WinGet, isMaximised, MinMax

        ;Clear any context menus
        Send {Escape down}{Escape up}

        ;Right click near the song title in the "Now Playing" box.
        WinGetPos,  ,  ,  , spotifyHeight, %spotify%
        MouseClick, Right, 44, spotifyHeight - (isMaximised = 1 ? 75 : 66), 1, 0
        sleep 200
        MouseMove 10,0, ,R
        sleep 200

        ; Determine if the song is already added to your library or not
        ; Look at left edge of the 'S' in Save to Your Library
        ; or the 'R' in Remove from Your Library
        ; 0x282828 is the background color of the menu
        ; if the background color is not present then the song is not in your library
        PixelGetColor, pixelColor, 91, spotifyHeight - (isMaximised = 1 ? 129 : 119)
        if (pixelColor = 0x282828) {
            ;Move up to 'Save to Your Library' and hit enter
            loop, 1 {
                Send {Up down}
                sleep 50
                Send {Up up}
                sleep 50
            }
            Send {Enter down}
            sleep 50
            Send {Enter up}
            sleep 50
        } else {
            ; Already added, so close context menu
            Send {Escape down}
            sleep 50
            Send {Escape up}
            Sleep 50
        }

        ;Restore original window and mouse position.
        IfEqual MMX, -1, WinMinimize, %spotify%
        WinActivate ahk_id %winID%
        MouseMove %x%, %y%

    }
    Return
}