Como forço o Windows a verificar se há atualizações?

Após uma nova instalação do Windows - XP ou 7 - como posso "forçar" as atualizações do Windows?

Não quero receber atualizações "antigas" do Windows depois de uma semana; isso poderia ser feito em "uma etapa"? Existem comandos "mágicos" que forçam o Windows a verificar se há atualizações? Se houver algum, instale-os?

Você pode procurar e instalar atualizações automaticamente usando um script. Isso funcionará no XP ou no Windows 7.

Há vários scripts disponíveis para download, aqui é o meu :

' Written in 2007 by Harry Johnston, University of Waikato, New Zealand.
' This code has been placed in the public domain.  It may be freely
' used, modified, and distributed.  However it is provided with no
' warranty, either express or implied.
'
' Exit Codes:
'   0 = scripting failure
'   1 = error obtaining or installing updates
'   2 = installation successful, no further updates to install
'   3 = reboot needed; rerun script after reboot
'
' Note that exit code 0 has to indicate failure because that is what
' is returned if a scripting error is raised.
'

Set updateSession = CreateObject("Microsoft.Update.Session")

Set updateSearcher = updateSession.CreateUpdateSearcher()
Set updateDownloader = updateSession.CreateUpdateDownloader()
Set updateInstaller = updateSession.CreateUpdateInstaller()

Do

  WScript.Echo
  WScript.Echo "Searching for approved updates ..."
  WScript.Echo

  Set updateSearch = updateSearcher.Search("IsInstalled=0")

  If updateSearch.ResultCode <> 2 Then

    WScript.Echo "Search failed with result code", updateSearch.ResultCode
    WScript.Quit 1

  End If

  If updateSearch.Updates.Count = 0 Then

    WScript.Echo "There are no updates to install."
    WScript.Quit 2

  End If

  Set updateList = updateSearch.Updates

  For I = 0 to updateSearch.Updates.Count - 1

    Set update = updateList.Item(I)

    WScript.Echo "Update found:", update.Title

  Next

  WScript.Echo

  updateDownloader.Updates = updateList
  updateDownloader.Priority = 3

  Set downloadResult = updateDownloader.Download()

  If downloadResult.ResultCode <> 2 Then

    WScript.Echo "Download failed with result code", downloadResult.ResultCode
    WScript.Echo

    WScript.Quit 1

  End If

  WScript.Echo "Download complete.  Installing updates ..."
  WScript.Echo

  updateInstaller.Updates = updateList

  Set installationResult = updateInstaller.Install()

  If installationResult.ResultCode <> 2 Then

    WScript.Echo "Installation failed with result code", installationResult.ResultCode

    For I = 0 to updateList.Count - 1

      Set updateInstallationResult = installationResult.GetUpdateResult(I)
      WScript.Echo "Result for " & updateList.Item(I).Title & " is " & installationResult.GetUpdateResult(I).ResultCode

    Next

    WScript.Quit 1

  End If

  If installationResult.RebootRequired Then

    WScript.Echo "The system must be rebooted to complete installation."

    WScript.Quit 3

  End If

  WScript.Echo "Installation complete."

Loop 

Você executa isso na linha de comando da seguinte maneira:

cscript wsusupdate.vbs

Meu script é minimamente funcional, mas ainda pode ser útil. Existem outros scripts disponíveis com muitos recursos adicionais, tente uma pesquisa no Google.

Além da maneira usual de usar o Windows Update, você pode forçar uma verificação em uma linha de comando.

Abra um prompt de comando do administrador e execute:

C:\> %windir%\system32\wuauclt.exe /detectnow

O Wuauclt.exe é o Cliente do AutoUpdate do Windows Update e é usado para verificar as atualizações disponíveis (para as várias versões da plataforma MS Windows) do Microsoft Update.

Isso não forçará uma instalação.

Para verificar se há atualizações, vá para Painel de Controle, Segurança, Windows Update e clique em "Verificar atualizações".

Outra maneira de forçar uma verdadeira nova varredura para atualizações é limpar o slate, excluindo todas as atualizações armazenadas em % windir% \ Windows \ SoftwareDistribution \ Download :

    NET STOP wuauserv
    RD /S /Q %windir%\SoftwareDistribution\Download
    NET START wuauserv

Em seguida, vá para o Windows Update e "Verifique se há atualizações". Pode levar uma hora, porque todos os arquivos atualizáveis ​​no volume do sistema são verificados (as "verificações de atualizações" subsequentes serão rápidas). Essa abordagem elimina erros, atualizações incorretas e gera um sistema limpo e atualizado, pelo menos na medida em que a MS o vê.

Estou usando uma ferramenta de segunda parte chamada wuinstall para atualizar a instalação do Windows. com isso, você pode automatizar todo o processo de atualização, incluindo reinicializações automáticas. Eu acho que é uma das maneiras mais rápidas de atualizar o Windows sem a presença do usuário.

Descobri que se, como parte de sua nova instalação no Windows 7, você atualizou o IE ou ainda não o executou e respondeu às perguntas introdutórias, o Windows Update apresentará um erro. Também não encontrei uma maneira de alternar o Windows Update para o Microsoft Update sem passar pela GUI; portanto, inicio manualmente o IE, inicializo-o e configuro o Windows Update através da GUI, para poder alternar para o Microsoft Update e evitar a erro inicial. Sua milhagem pode variar.

Tive sucesso ao seguir as etapas deste post , ao instalar o IE8 e o WI4.5 , ele acionará atualizações automáticas para iniciar downloads.