Como posso atualizar automaticamente o Flash Player sempre que uma nova versão é lançada?

Resumo:

O Flash Player Update Service não executar em um cronograma confiável, e não o download e aplicar as atualizações quando ele automaticamente faz correr.

Dada a importância de ter uma versão atualizada do Flash Player instalada (para aqueles que não usam o Chrome com o player incorporado), gostaria de encontrar uma maneira de garantir que novas atualizações sejam detectadas prontamente e instalado.

A seguir, são apresentados os detalhes dos meus esforços para resolver esse problema por conta própria ...

Apêndice A: Serviço de Atualização do Flash Player

OK, já no Flash Player 11.2 (mais ou menos?) A Adobe adicionou o Serviço de Atualização do Flash Player (FlashPlayerUpdateService.exe), que deveria manter o Flash Player atualizado ...

• Após a instalação, o FPUS é configurado para ser executado como um serviço do Windows, com o Tipo de início definido como Manual.

• Uma tarefa agendada (Adobe Flash Player Updater.job) é adicionada para iniciar esse serviço a cada hora.

Até agora, tudo bem - essa configuração evita ter um serviço em execução constante, mas garante que as verificações sejam executadas com frequência suficiente para capturar as atualizações rapidamente. Atualizador de software do Google está configurado de forma semelhante, e que funciona muito bem ...

... No entanto, quando verifiquei a versão do meu Flash Player instalado, descobri que era 11.6.602.180 , que, com base na observação dos carimbos de data e hora dos arquivos, C:\Windows\System32\Macromed\Flashfoi atualizado (ou instalado) pela última vez em terça - feira , 12 de março de 2013 --- 3/12/13, 17:00:08 .

Fiz essa observação em quinta-feira, 25 de abril de 2013 --- 25/4/13, 19:00:00 e, ao verificar o site da Adobe, descobri que a versão atual do Flash Player era 11.7.700.169 .

Isso ocorre há mais de um mês desde a última atualização, com uma nova claramente disponível no site, mas sem indicação de que a verificação horária em execução na minha máquina tenha notado ou pretenda baixá-la.

Apêndice B: executando o atualizador do Flash Player manualmente

Era uma vez, correr , uma janela com o botão Instalar ; pressioná-lo faria o download do instalador da versão atual (automaticamente, sem abrir um navegador) e o executaria; em seguida, você clicaria nesse instalador e pronto. Era manual, mas funcionou! Como minha instalação atual está desatualizada (consulte o Apêndice A), tentei pela primeira vez este processo de atualização manual. Contudo...FlashUtil32_<version>_Plugin.exe -update plugin

• Em execução (no meu caso, isso é ) ... apresenta apenas uma janela com um botão Download, clicando nesse botão Download para abrir meu navegador no URL https://get3.adobe.com/flashplayer/update/activex .FlashUtil32_<version>_ActiveX.exe -update activexFlashUtil32_11_6_602_180_ActiveX.exe -update activex

• Em execução (no meu caso, isso é ) ... apresenta apenas uma janela com um botão Download, clicando nesse botão Download para abrir meu navegador no URL https://get3.adobe.com/flashplayer/update/plugin .FlashUtil32_<version>_Plugin.exe -update pluginFlashUtil32_11_6_602_180_Plugin.exe -update plugin

Eu poderia continuar com a página de download para a qual me enviou, desmarcar a caixa de foistware ("Grátis! McAfee Security Scan Plus"), baixar o instalador (ActiveX, sem foistware: install_flashplayer11x32axau_mssd_aih.exe, Plugin, sem foistware: install_flashplayer11x32au_mssd_aih.exe) e provavelmente tem um Flash atualizado ... mas qual é o objetivo do Serviço de Atualização do Flash Player se eu precisar baixar e executar manualmente outro exe?

Epílogo

Desde então, suspeitei que o serviço de atualização foi intencionalmente prejudicado para levar os primeiros usuários à página de download manual. Se isso for verdade, provavelmente não há solução para esse problema em escrever meu próprio atualizador; espero que eu esteja errado.

Talvez o atualizador aplique apenas atualizações no intervalo 11.6.x?

Você sempre pode usar links diretos para os instaladores, que considero mais confiáveis: ActiveX ; Plugin .

Com este arquivo .bat, ele tentará atualizar ou instalar automaticamente o Flash Player para Internet Explorer, Firefox (SeaMonkey e etc), baseado em Chromium (Chrome, Opera 15+ e etc):

del install_flash_player.exe
del install_flash_player_ax.exe
del install_flash_player_ppapi.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe
install_flash_player.exe -install
install_flash_player_ax.exe -install
install_flash_player_ppapi.exe -install

Wget necessário, você pode fazer o download aqui e precisar colocá-lo no mesmo diretório em que .bat foi colocado.

Um exemplo um pouco mais avançado, escrito em Autoit .

Características: Verificação simples para nova versão, se aqui não houver uma nova versão, saia do programa sem baixar o instalador do flash player. Se o instalador do download falhar, mostre a caixa de mensagem com erro e saia. Janela de prompt de comando oculta. Não precisa do wget.

Depois de instalar o Autoit e o Editor . Clique com o botão direito na área de trabalho-> Novo-> Autoit Script. Clique com o botão direito no arquivo criado-> Editar. Agora você deve ver a janela do ScITE e, após a linha "Adicione seu código abaixo aqui", adicione este código:

#NoTrayIcon
#include <WinAPIDiag.au3>
$flashplayerlink="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe"
$flashplayername="install_flash_player.exe"
$flashplayerlinkAX="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe"
$flashplayernameAX="install_flash_player_ax.exe"
updateflashplayer($flashplayerlink,$flashplayername)
updateflashplayer($flashplayerlinkAX,$flashplayernameAX)

$flashplayerlinkPPAPI="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe"
$flashplayernamePPAPI="install_flash_player_ppapi.exe"
updateflashplayer($flashplayerlinkPPAPI,$flashplayernamePPAPI)



Func updateflashplayer($link,$fname)
    if FileGetSize($fname)<>InetGetSize($link) then
        InetGet($link,$fname)
        if @error then
            MsgBox(16,"","Error: '"&_WinAPI_GetErrorMessage(@error)&"'"&@CRLF&$fname)
            Exit
        EndIf
        RunWait($fname&" -install","",@SW_HIDE)
    EndIf
EndFunc

Em seguida, na janela do SciTE, pressione Ferramentas-> Construir ou pressione F7. Agora você será executável autônomo no mesmo diretório em que estava o script Autoit.

Eu recomendo criar uma nova pasta (com permissão de acesso de gravação) para este "atualizador". Você pode adicionar um atalho para esse "atualizador" para iniciar também.

Aqui aplicativo para desinstalar o flash player.

Quero compartilhar meu script em lote com você, salve este pedaço de código no seu bloco de notas e nomeie-o como Download_Install_Last_Flash_Player.bat

@echo off
REM Help page related to installation problems flash player windows (English)
REM English https://helpx.adobe.com/flash-player/kb/installation-problems-flash-player-windows.html
REM Page d'aide relative aux problèmes d'installation flash player windows (Français)
REM French https://helpx.adobe.com/fr/flash-player/kb/installation-problems-flash-player-windows.html
Mode 90,3 & color 9D
Title Download and install the latest version of Adobe Flash Player by Hackoo 2017
Set "Download_Folder=%~dp0Latest_Flash_Player_Installers"
Set "Uninstaller_Folder=%~dp0Uninstaller"
Set "Uninstaller_URL=https://fpdownload.macromedia.com/pub/labs/flashruntimes/flashplayer/uninstall_flash_player.exe"
Set "URL1=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe"
Set "URL2=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe"
Set "URL3=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe"
Set "URL_Help=https://helpx.adobe.com/flash-player/kb/installation-problems-flash-player-windows.html"
If Not Exist "%Uninstaller_Folder%" MD "%Uninstaller_Folder%"
If Not Exist "%Download_Folder%" MD "%Download_Folder%"
Call :Killing_Running_Browsers
Rem We Play radio just for fun and in order to let the user be patient until the download ended
Call :Play_DJ_Buzz_Radio
Call :Uninstalling_Flash_Player
Call :Download_and_Install_Flash_Player
REM Just to check (Check Button on the web page) if the latest Adobe Flash Player is installed successfully or not !
Start "Help page" "%URL_Help%" & Call :Stop_Radio & Exit
::***************************************************************************************************
:Uninstalling_Flash_Player
cls & echo( 
@For %%i in (%Uninstaller_URL%) do Set "Uninstaller_File=%%~nxi"
Call :Download "%Uninstaller_URL%" "%Uninstaller_Folder%\%Uninstaller_File%"
echo    Unistalling older and previous version of Adobe Flash Player ...
%Uninstaller_File% -uninstall
exit /b
::***************************************************************************************************
:Killing_Running_Browsers
set "Browsers_List=firefox chrome iexplore opera"
cls & echo(
echo     Killing any running instances of those browsers "%Browsers_List%" ...
@For %%i in (%Browsers_List%) Do ( 
    Taskkill /IM "%%i.exe" /F>nul 2>&1
)
exit /b
::***************************************************************************************************
:Download_and_Install_Flash_Player
@For %%i in (%URL1%) do Set "File1=%%~nxi"
Call :Download "%URL1%" "%Download_Folder%\%File1%"
Call :Installing_Flash_Player "%Download_Folder%\%File1%"
@For %%i in (%URL2%) do Set "File2=%%~nxi"
Call :Download "%URL2%" "%Download_Folder%\%File2%"
Call :Installing_Flash_Player "%Download_Folder%\%File2%"
@For %%i in (%URL3%) do Set "File3=%%~nxi"
Call :Download "%URL3%" "%Download_Folder%\%File3%"
Call :Installing_Flash_Player "%Download_Folder%\%File3%"
exit /b
::***************************************************************************************************
:Installing_Flash_Player <Install_File>
cls & color 9B
echo(
echo   Please wait a while ... installing "%~nx1" is in progress ...
%1 -install
exit /b
::***************************************************************************************************
:Download <url> <File>
cls & color 0A
echo(
echo      Please wait a while ... Downloading "%~n2" is in progress ...
Powershell.exe -command "(New-Object System.Net.WebClient).DownloadFile('%1','%2')"
exit /b
::***************************************************************************************************
:Play_DJ_Buzz_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
Set "vbsfile=%temp%\DJBuzzRadio.vbs"
Set "URL=http://www.chocradios.ch/djbuzzradio_windows.mp3.asx"
Call:Play "%URL%" "%vbsfile%"
Start "" "%vbsfile%"
Exit /b
::**************************************************************
:Play
(
echo Play "%~1"
echo Sub Play(URL^)
echo    Dim Sound
echo    Set Sound = CreateObject("WMPlayer.OCX"^)
echo    Sound.URL = URL
echo    Sound.settings.volume = 100
echo    Sound.Controls.play
echo    do while Sound.currentmedia.duration = 0
echo       wscript.sleep 100
echo    loop
echo    wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000
echo End Sub
)>%~2
exit /b
::**************************************************************
:Stop_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
If Exist "%vbsfile%" Del "%vbsfile%"
::**************************************************************