Configurar o VIM para copiar e colar atalhos de teclado do buffer do sistema no Ubuntu?

Como configurar o VIM para usar Ctrl- cpara copiar e Ctrl- vcolar do buffer do sistema no Ubuntu?

Comportamento padrão no MS Windows: -

Aqui está um trecho do arquivo mswin.vim: -

" CTRL-X and SHIFT-Del are Cut
vnoremap <C-X> "+x
vnoremap <S-Del> "+x

" CTRL-C and CTRL-Insert are Copy
vnoremap <C-C> "+y
vnoremap <C-Insert> "+y

" CTRL-V and SHIFT-Insert are Paste
map <C-V>       "+gP
map <S-Insert>      "+gP

cmap <C-V>      <C-R>+
cmap <S-Insert>     <C-R>+

" Pasting blockwise and linewise selections is not possible in Insert and
" Visual mode without the +virtualedit feature.  They are pasted as if they
" were characterwise instead.
" Uses the paste.vim autoload script.

exe 'inoremap <script> <C-V>' paste#paste_cmd['i']
exe 'vnoremap <script> <C-V>' paste#paste_cmd['v']

imap <S-Insert>     <C-V>
vmap <S-Insert>     <C-V>

" Use CTRL-Q to do what CTRL-V used to do
noremap <C-Q>       <C-V>

e o script paste.vim necessário para o modo de bloco recortar / colar: -

    " Vim support file to help with paste mappings and menus
" Maintainer:   Bram Moolenaar <[email protected]>
" Last Change:  2006 Jun 23

" Define the string to use for items that are present both in Edit, Popup and
" Toolbar menu.  Also used in mswin.vim and macmap.vim.

" Pasting blockwise and linewise selections is not possible in Insert and
" Visual mode without the +virtualedit feature.  They are pasted as if they
" were characterwise instead.  Add to that some tricks to leave the cursor in
" the right position, also for "gi".
if has("virtualedit")
  let paste#paste_cmd = {'n': ":call paste#Paste()<CR>"}
  let paste#paste_cmd['v'] = '"-c<Esc>' . paste#paste_cmd['n']
  let paste#paste_cmd['i'] = 'x<BS><Esc>' . paste#paste_cmd['n'] . 'gi'

  func! paste#Paste()
    let ove = &ve
    set ve=all
    normal! `^
    if @+ != ''
      normal! "+gP
    endif
    let c = col(".")
    normal! i
    if col(".") < c " compensate for i<ESC> moving the cursor left
      normal! l
    endif
    let &ve = ove
  endfunc
else
  let paste#paste_cmd = {'n': "\"=@+.'xy'<CR>gPFx\"_2x"}
  let paste#paste_cmd['v'] = '"-c<Esc>gix<Esc>' . paste#paste_cmd['n'] . '"_x'
  let paste#paste_cmd['i'] = 'x<Esc>' . paste#paste_cmd['n'] . '"_s'
endi

Isso é mínimo, assumindo que a maioria das coisas são configurações padrão **:

:behave mswin
:set clipboard=unnamedplus
:smap <Del> <C-g>"_d
:smap <C-c> <C-g>y
:smap <C-x> <C-g>x
:imap <C-v> <Esc>pi
:smap <C-v> <C-g>p
:smap <Tab> <C-g>1> 
:smap <S-Tab> <C-g>1<

• linha 1: faz com que as teclas shift + selecionem texto (e faz mais *)

• linha 2: torna "+ (e" *) o registro padrão (gui / term clipboard)

• linhas 3,4,5,6: faz Ctrl-x / c / v Recortar / Copiar e Colar

• linha 7,8: faz as seleções de recuo / recuo de TAB / SHIFT + TAB

Cuidado: as configurações [: set] podem alterar esse comportamento e que muitos ajustes podem ser necessários para atender às suas necessidades, como eu disse, no mínimo. * [: se comporta] altera muitas coisas [: configurações], leia os documentos.

Mapeie Ctrl-V para executar o comando do sistema que agarra a área de transferência do sistema e a lança em um registro e cola-a na tela sob o cursor:

vmap <C-c> y:call system("xclip -i -selection clipboard", getreg("\""))<CR>:call system("xclip -i", getreg("\""))<CR>
nmap <C-v> :call setreg("\"",system("xclip -o -selection clipboard"))<CR>p

Fonte: http://vim.wikia.com/wiki/In_line_copy_and_paste_to_system_clipboard