Desativar ou atrasar o efeito Alt + Tab Aero Peek no Windows 7

No Windows 7, pressionar Alt+ Tabmostra o efeito de janelas transparentes (Aero). A alteração da tela é perturbadora enquanto estou tentando descobrir para qual janela mudar com base na visualização de miniaturas (o que é suficiente para mim na maioria das vezes). Existe alguma maneira de desativar o efeito Aero Peek ou atrasar sua ativação para algo em torno de 6 segundos?

Na barra de tarefas, o efeito Aero Peek é exibido sob demanda quando passo o mouse sobre as miniaturas reais. Esse comportamento não é um problema e, se eu tiver uma escolha, não quero que seja desativado.

Você pode encontrar vistaswitcher mais ao seu gosto. Ele fornece uma caixa de visualização instantânea no meio da tela (configurável), sem diminuir a transparência lenta. Tente!

Não há como desativar adequadamente o aero peek apenas com alt-tab, mas você pode definir o atraso para um valor absurdamente alto, desativando-o efetivamente. Há outro post detalhando esse processo. Essencialmente, você precisa criar o valor DWORD LivePreview_msem HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\AltTabum número muito grande. Essa chave armazena o tempo em milissegundos para atrasar, então 60000 deve ser suficiente, pois duvido que você mantenha a tecla Alt pressionada por mais de um minuto.

Observe que configurar a chave do Registro para 0desabilitar totalmente o Aero-peek para Alt-Tab. Você precisa sair e entrar novamente para que a alteração entre em vigor.

Você pode corrigir isso no desempenho; Eu tive o mesmo problema. Não é "nosso cérebro que está com problemas", é uma usabilidade de baixa qualidade devido ao inchaço dos recursos. Alt-tab era mais ou menos perfeito no Vista.

Acesse Ajustar efeitos visuais (em Desempenho no painel de controle) e desmarque Aero Peek.

Outro truque que você pode fazer é usar a guia alt "antiga" que está presente no Windows 7:

1. Mantenha pressionada a tecla alt esquerda
2. Toque na tecla alt direita
3. Ainda segurando o alt esquerdo, use a tecla tab como faria normalmente para percorrer as tarefas

Você notará que isso usa o antigo alternador de estilo alt-tab e não diminui as janelas para você.

Você pode estar interessado em um recurso do Windows 7 que é um pouco semelhante ao alt-tab: WinKey + 1, WinKey + 2, WinKey + 3, etc. Essas teclas de atalho ativam as janelas na barra de tarefas nas posições 1, 2, 3, etc.

Se você fixar os programas usados ​​com freqüência na barra de tarefas, eles sempre estarão em uma determinada "posição de slot" na barra de tarefas. Por esse motivo, será fácil memorizar quais WinKey + N se alinham com qual programa. Pressionar WinKey + N repetidamente fará "alt tab" através das janelas abertas desse programa. Acho isso particularmente útil nas janelas do Windows Explorer, porque muitas vezes tenho muitas delas abertas.

Sei que esse é um tópico bastante antigo, mas também nunca gostei do recurso Areo Peek ao usar Alt+ TABpara alternar tarefas. Além disso, não recuso completamente o Areo Peek - por exemplo, gosto de dar uma olhada na minha área de trabalho do Windows usando o WIN+ Space.

Eu tentei um monte desativar Areo Peek apenas somente para Alt+ TABalternância de tarefas, mas nada realmente funcionou para mim. Conheço todas as dicas de registro, por exemplo, definindo o atraso do Aero Peek em milissegundos para um valor muito alto. Mas isso não funciona, pelo menos não em todas as máquinas - pela minha experiência, você pode definir um valor alto que ainda é limitado a 3000 ms internamente (talvez isso tenha funcionado antes do Service Pack para Windows 7).

Por isso, decidi seguir outro caminho e tentar resolver esse problema via AutoHotkey . Esse script desativa o Aero Peek apenas para Alt+ TABe somente para isso - para que você ainda possa usar os outros recursos do Aero Peek.

O script é testado na versão AutoHotkey "AutoHotkey_L 1.1.00.00" com o Windows 7 Professional de 64 bits com um usuário do Windows com direitos de administrador - e até agora foi relatado que funcionava em todos os sistemas dos quais recebi feedback. Basta instalar o AutoHotkey e defina o arquivo de script para ser executado automaticamente quando o Windows iniciar. É muito leve, usando apenas muito poucos recursos e tempo de CPU.

Acabei de publicá-lo aqui na esperança de que isso ajude qualquer pessoa com esse problema. Faça o download do script em:

http://dl.dropbox.com/u/15020526/Privat/Software/GA/AutoHotkey/DisableAeroPeekForAltTab_1.0.zip

; ==============================================================
;
; AVOID "AERO PEEK" FOR ALT-TAB - AUTOHOTKEY-SCRIPT
; 
; Disables Windows 7 Areo Peek feature for ALT-TAB, and only 
; for this, so that other Areo Peek features (like WIN+SPACE) 
; can still be used.
;
; This script can be run with AutoHotkey (http://www.autohotkey.com/),
; tested against Version AutoHotkey_L 1.1.00.00 with Windows 7 
; Professional 64 bit with a Windows user with admin rights.
;
; @author   Timo Rumland <timo.rumland${at}the-cr.de>, 19.09.2011
; @version  1.0
;
; --------------------------------------------------------------
;
; LICENSE
; 
; This software is distributed under the FreeBSD License.
;
; Copyright (c) 2011 Timo Rumland <timo.rumland${at}the-cr.de>. All rights reserved.
; 
; Redistribution and use in source and binary forms, with or without modification, are
; permitted provided that the following conditions are met:
; 
;    1. Redistributions of source code must retain the above copyright notice, this list of
;       conditions and the following disclaimer.
; 
;    2. Redistributions in binary form must reproduce the above copyright notice, this list
;       of conditions and the following disclaimer in the documentation and/or other materials
;       provided with the distribution.
; 
; THIS SOFTWARE IS PROVIDED BY <COPYRIGHT HOLDER> ''AS IS'' AND ANY EXPRESS OR IMPLIED
; WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND
; FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL <COPYRIGHT HOLDER> OR
; CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON
; ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
; NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
; ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
; 
; The views and conclusions contained in the software and documentation are those of the
; authors and should not be interpreted as representing official policies, either expressed
; or implied, of <copyright holder>.
;
; ==============================================================

#NoEnv
#SingleInstance     force
SendMode            Input 
SetWorkingDir       %A_ScriptDir%
SetTitleMatchMode   2       ; 2: A window's title can contain WinTitle anywhere inside it to be a match. 


; =======
; Global
; =======

    visualEffectsRegistryKey                := Object()
    visualEffectsRegistryKey.valueType      := "REG_DWORD"
    visualEffectsRegistryKey.rootKey        := "HKEY_CURRENT_USER"
    visualEffectsRegistryKey.subKey         := "Software\Microsoft\Windows\CurrentVersion\Explorer\VisualEffects"
    visualEffectsRegistryKey.valueName      := "VisualFXSetting"
    visualEffectsRegistryKey.value          := 3    ; Manual Visual FX Settings

    enableAeroPeekRegistryKey               := Object()
    enableAeroPeekRegistryKey.valueType     := "REG_DWORD"
    enableAeroPeekRegistryKey.rootKey       := "HKEY_CURRENT_USER"
    enableAeroPeekRegistryKey.subKey        := "Software\Microsoft\Windows\DWM"
    enableAeroPeekRegistryKey.valueName     := "EnableAeroPeek"
    enableAeroPeekRegistryKey.enabledValue  := 1
    enableAeroPeekRegistryKey.disabledValue := 0


; ===============
; Initialization
; ===============

    ; Initially write "VisualFXSetting" registry key to "manual settings"
    writeRegistryKey( visualEffectsRegistryKey, visualEffectsRegistryKey.value )


; ========
; Hotkeys
; ========

    ; -----------------------------------------------------------------------------
    ; This is the ALT-TAB hotkey that triggers setting Aero Peek to disabled 
    ; right before Windows displays the ALt-TAB-Menu. After releasing the ALT-key,
    ; Areo Peek will be enabled again.
    ; -----------------------------------------------------------------------------
    ~!Tab::

        writeRegistryKey( enableAeroPeekRegistryKey, enableAeroPeekRegistryKey.disabledValue )
        KeyWait Alt
        writeRegistryKey( enableAeroPeekRegistryKey, enableAeroPeekRegistryKey.enabledValue )

    return


; ==========
; Functions
; ==========

    ; ----------------------------------------------------------------------
    ; Writes the given value to the given registry key. The "registryKey"
    ; is an object with the properties "valueType", "rootKey", "subKey" and
    ; "valueName", suitable to the AHK function "RegWrite".
    ; ----------------------------------------------------------------------
    writeRegistryKey( registryKey, value )
    {
        valueType   := registryKey.valueType
        rootKey     := registryKey.rootKey
        subKey      := registryKey.subKey
        valueName   := registryKey.valueName

        RegWrite %valueType%, %rootKey%, %subKey%, %valueName%, %value%
    }

Você pode distribuí-lo livremente, sob a licença FreeBSD.

Você pode passar o mouse sobre a visualização de miniaturas no centro da tela enquanto mantém as teclas ALT + Tab pressionadas. Apesar das janelas de fundo ainda estarem em ciclo, o movimento do mouse focará sua atenção nas miniaturas. Acho isso menos confuso do que pressionar repetidamente a guia enquanto o ALT está deprimido. Você então clica na janela que deseja mover.

Além disso, o Win + Tab também é menos confuso. Você pode se acostumar com isso mais rápido que Alt + Tab.

Observe também que você pode fazer o oposto. Até o momento, fomos treinados a prestar atenção nas miniaturas centrais. Porém, com a ciclagem de janelas oferecida com o ALT + TAB, você pode começar a desconsiderar as miniaturas centrais e, em vez disso, concentrar sua atenção no ciclo das janelas. Depois de um tempo, tenho certeza de que você estará se perguntando por que isso foi um problema para você. Está tudo em nosso cérebro :)

Você pode desativar o Aero Peek por apenas ALT+TAB

A solução é definir o seguinte valor do Registro, que restaura o comportamento do Windows XP-Style de ALT+ TAB:

1. Execute REGEDIT.EXE
2. Navegar para HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer
3. Crie um novo valor DWORD nomeado AltTabSettingse defina seu valor como1
4. A alteração entra em vigor imediatamente.

_{crédito: Esta resposta do superusuário}

A resposta vinculada também fornece um comando do PowerShell que cria o valor acima:

Set-ItemProperty HKCU:\Software\Microsoft\Windows\CurrentVersion\Explorer AltTabSettings ([int]1)