Como calcular o número de meses entre duas datas no Excel? [duplicado]

8

Eu tenho duas colunas no Microsoft Excel: F é a coluna com a data em que o serviço terminou; E é a coluna com a data em que o serviço começou.

Como faço para calcular e informar o número de meses atendidos por cada pessoa?

microsoft-excel Terrance Drake
fonte
Diga-nos o resultado desejado com (por exemplo) 14.3.2014 - 12.7.2014: (a) 4 meses (o quarto não está completo) ou (b) 5 meses (contando todos os meses tocados) ou (c) 3 meses (apenas contagem completa dos meses) ou (d) 3,9 meses.
guntbert
11
A resposta aqui é melhor do que o 'original' vinculado nesta pergunta
Jayan

Respostas:

16

A função DATEDIF fornece explicitamente o número de meses entre duas datas - é arredondada para baixo

=DATEDIF(A2,B2,"m")

onde A2 é a primeira das duas datas

Se você deseja arredondar para o mês inteiro "mais próximo", pode usar esta versão

=DATEDIF(A2,B2+15,"m")

Se você não se importa com o dia e qualquer data de janeiro para qualquer data de março é de 3 meses, pode usar esta versão

=DATEDIF(A2-DAY(A2)+1,B2,"m")+1

barry houdini
fonte
Também funciona no Planilhas Google.
Adriano P
Você pode usar =(B2 - A1)/(365/12)se você quiser uma resposta não-arredondado, que considera um mês sendo em média 365/12 dias de duração
aljgom
3

Há um KB da Microsoft abordando esse mesmo tópico aqui

Ele fornece duas soluções, dependendo se você deseja arredondar os meses para baixo ou para cima.

Arredondar para cima:

=(YEAR(LDate)-YEAR(EDate))*12+MONTH(LDate)-MONTH(EDate)

Arredondar para baixo:

=IF(DAY(LDate)>=DAY(EDate),0,-1)+(YEAR(LDate)-YEAR(EDate))*12+MONTH(LDate)-MONTH(EDate)

Nos dois casos, EDate é a célula que contém a data anterior e LDate é a célula que contém a data posterior.

kenkh
fonte