Conclusão da guia zsh na linha vazia

Gostaria de um tcsh'ism que não consegui encontrar: Em uma linha em branco sem conteúdo, quero pressionar a tecla Tab e ver o equivalente a ls. Ou seja, eu quero

$ <tab>

para fazer outra coisa além de me dar uma \ t. Encontrei recursos fantásticos para a conclusão de comandos, mas não para este caso base. Qualquer ajuda nisso seria ótimo! Obrigado.

# expand-or-complete-or-list-files
function expand-or-complete-or-list-files() {
    if [[ $#BUFFER == 0 ]]; then
        BUFFER="ls "
        CURSOR=3
        zle list-choices
        zle backward-kill-word
    else
        zle expand-or-complete
    fi
}
zle -N expand-or-complete-or-list-files
# bind to tab
bindkey '^I' expand-or-complete-or-list-files

O comportamento de Tabno início de uma linha é controlado pelo estilo . No entanto, existem apenas dois comportamentos suportados:insert-tab

• conclusão, como de costume, sob zstyle ':completion:*' insert-tab false
• insira uma guia, em zstyle ':completion:*' insert-tab true
• um ou outro em zstyle ':completion:*' insert-tab pending[=N]

Se você apenas deseja concluir os comandos nessa posição, zstyle ':completion:*' insert-tab truefará. Se você quiser algo diferente, como listar os arquivos no diretório atual, precisará modificar _main_complete.

Um tópico recente na lista zsh-workers discutido insert-tab.

Aqui está a implementação completa da lista automática do tcsh no zsh, quando você pressiona tab na linha vazia

% <TAB>

Aqui está:

# list dir with TAB, when there are only spaces/no text before cursor,
# or complete words, that are before cursor only (like in tcsh)
tcsh_autolist() { if [[ -z ${LBUFFER// } ]]
    then BUFFER="ls " CURSOR=3 zle list-choices
    else zle expand-or-complete-prefix; fi }
zle -N tcsh_autolist
bindkey '^I' tcsh_autolist

Se você deseja emular o tcsh mais de perto, adicione-o ao seu .zshrc:

unsetopt always_last_prompt       # print completion suggestions above prompt

Eu escrevi este widget zsh que aprimora o uso do TAB, não apenas em uma linha vazia, mas também enquanto você digita um comando.

• Ele listará os arquivos em uma linha de comando vazia e no meio de qualquer comando.
• Ele listará os diretórios em uma linha de comando vazia.
• Ele listará os executáveis em uma linha de comando vazia.

Ele pode ser configurado para incluir "cd" ou "./" nesses casos com uma variável global.

export TAB_LIST_FILES_PREFIX

# List files in zsh with <TAB>
#
# Copyleft 2017 by Ignacio Nunez Hernanz <nacho _a_t_ ownyourbits _d_o_t_ com>
# GPL licensed (see end of file) * Use at your own risk!
#
# Usage:
#   In the middle of the command line:
#     (command being typed)<TAB>(resume typing)
#
#   At the beginning of the command line:
#     <SPACE><TAB>
#     <SPACE><SPACE><TAB>
#
# Notes:
#   This does not affect other completions
#   If you want 'cd ' or './' to be prepended, write in your .zshrc 'export TAB_LIST_FILES_PREFIX'
#   I recommend to complement this with push-line-or edit (bindkey '^q' push-line-or-edit)
function tab_list_files
{
  if [[ $#BUFFER == 0 ]]; then
    BUFFER="ls "
    CURSOR=3
    zle list-choices
    zle backward-kill-word
  elif [[ $BUFFER =~ ^[[:space:]][[:space:]].*$ ]]; then
    BUFFER="./"
    CURSOR=2
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER="  " CURSOR=2
  elif [[ $BUFFER =~ ^[[:space:]]*$ ]]; then
    BUFFER="cd "
    CURSOR=3
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER=" " CURSOR=1
  else
    BUFFER_=$BUFFER
    CURSOR_=$CURSOR
    zle expand-or-complete || zle expand-or-complete || {
      BUFFER="ls "
      CURSOR=3
      zle list-choices
      BUFFER=$BUFFER_
      CURSOR=$CURSOR_
    }
  fi
}
zle -N tab_list_files
bindkey '^I' tab_list_files

# uncomment the following line to prefix 'cd ' and './' 
# when listing dirs and executables respectively
#export TAB_LIST_FILES_PREFIX

# these two lines are usually included by oh-my-zsh, but just in case
autoload -Uz compinit
compinit

# uncomment the following line to complement tab_list_files with ^q
#bindkey '^q' push-line-or-edit

# License
#
# This script is free software; you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This script is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this script; if not, write to the
# Free Software Foundation, Inc., 59 Temple Place, Suite 330,
# Boston, MA  02111-1307  USA