Uma fórmula de planilha para atribuir notas de letras com base em intervalos numéricos

8

Eu estou tentando descobrir como escrever uma instrução SE que será 'verdadeira' se um valor estiver entre dois valores.

Exemplo:

Se o valor estiver entre 60 e 69,9, retorne "D"

Se o valor estiver entre 70 e 79,9, retorne "C"

Se o valor estiver entre 80 e 89,9, retorne "B"

Eu tenho isso, mas não consigo descobrir como modificá-lo, portanto o teste é intermediário, em vez de menor ou maior que.

=IF(A1<60, "F", IF(A1>60, "A", 0))
google-sheets formulas worksheet-function Mr. B
fonte

Respostas:

8

Mantenha os sinais de desigualdade indo na mesma direção: 

=IF(A1<60, "F", IF(A1<70, "D", IF(A1<80, "C", IF(A1<90, "B", "A"))))

O acima funciona bem, desde que não haja muitos casos. Mas se você tivesse muitas opções, C-, C +, B-, B + ... seria melhor usar uma tabela de pesquisa. Por exemplo, se você tiver uma tabela de pesquisa como a abaixo,

=vlookup(A1, $K$1:$L$5)

faz o mesmo trabalho que os IFs aninhados. A tabela também é mais fácil de manter em caso de alterações: por exemplo, você decidiu mudar alguns pontos de corte.

+---+----+---+
|   | K  | L |
+---+----+---+
| 1 |  0 | F |
| 2 | 60 | D |
| 3 | 70 | C |
| 4 | 80 | B |
| 5 | 90 | A |
+---+----+---+

fonte
Não é necessário um terceiro argumento para vlookup no Google Docs?
Ellen Spertus 17/10
3

Outra solução, retirada do Fórum de Ajuda do Google Docs , mantém os pontos de corte diretamente na fórmula, eliminando-os separadamente.

Para os pontos de corte definidos no OP, a fórmula é

=VLOOKUP($A1,{0,"F";60,"D";70,"C";80,"B";90,"A"},2)

Alterar os interruptores pode parecer complicado agora, mas pode ser feito com eficiência da seguinte maneira. Altere os pontos de corte na fórmula na célula superior e, em seguida fill down, faça um CMD-Dou CTRL-Ddependendo da sua plataforma.

wsaleem
fonte
3

Modifiquei os pontos de corte de @ wsaleem para incluir - / + notas (por escala na minha faculdade):

=VLOOKUP(BB2,{0,"F";60,"D-";63,"D";68,"D+";70,"C-";73,"C";78,"C+";80,"B-";83,"B";88,"B+";90,"A-";93,"A"},2)

Certifique-se de ROUND () seu valor de entrada. Eu estava usando AVERAGE () e, embora o campo estivesse visivelmente arredondado, o valor não era.

ow3n
fonte
Estou tentando converter uma nota de carta em um número GPA. Tentei o seguinte VLOOKUP, quando a nota da letra está na coluna O: = vlookup ($ O2, {F, "0"; D, "1.0"; C -, "1.67"; C, "2.0"; C +, " 2,33 "; B -," 2,67 "; B," 3,0 "; B +," 3,33 "; A -," 3,67 "; A," 4,0 "} 2) Eu realmente não sei o que estou fazendo. O que é esse último "2" depois do parêntese final, mas antes dos parênteses finais?
user205307
Está faltando uma vírgula entre o intervalo e os 2 (esses são parâmetros separados por vírgula). Confira a documentação support.google.com/docs/answer/3093318?hl=en
ow3n