Concatene várias colunas em uma no Planilhas Google

15

insira a descrição da imagem aqui

Quero concatenar / combinar as colunas A, B e C na coluna D, conforme exibido.

O número de entradas preenchidas em A, B e C varia ao longo do tempo, portanto, endereços absolutos de célula não podem ser usados.

Que fórmula eu poderia colocar em D1 para preencher a coluna como ilustrado?

google-sheets concatenate Paulb
fonte
Estou ciente de que "anexar" pode ter sido um vocabulário melhor do que "concatenar". Como concatenar é algo que você costuma fazer com valores individuais.
paulb
1
Talvez seja a melhor resposta para mesclar para manipulação estatística aqui, onde você não precisa filtrar aqui webapps.stackexchange.com/a/69049/66725 Então, basta usar = {A1:A; B1:B}. Etc para contar correspondências únicas em duas colunas = count(unique(A1:A; B1:B})).
Léo Léopold Hertz,

Respostas:

9

Você precisa filtrar para células não vazias e empilhar os resultados juntos:

={filter(A:A, len(A:A)); filter(B:B, len(B:B)); filter(C:C, len(C:C))}

É o mesmo que a resposta de grayob, que infelizmente está oculta sob respostas desatualizadas.

user79865
fonte
1
Funcionou perfeitamente. Vi que Q e eu nos concentramos no vmerge, sem sucesso. Nesse Q, a resposta de grayob é melhor que a resposta aceita. Tks.
Paulb
13

Uma versão mais curta da fórmula nesta outra resposta

=FILTER({A:A;B:B;C:C}, LEN({A:A;B:B;C:C}))
Rubén
fonte
3

Um pouco mais, mas pode ser restrito a uma matriz limitada (não colunas inteiras):

=transpose(split(textjoin("|",1,{A1:C4}),"|"))

onde o pedido não importa. Onde faz:

=transpose(split(textjoin("|",1,{A1:A4;B1:B4;C1:C4}),"|"))
nozes
fonte
Esta é a minha solução favorita para este problema, não requer que seja nomeada todas as colunas. Você também pode classificar a primeira solução em que deseja que ela seja alfabetizada.
Lou